Filemaker XSL按名稱選擇列

Question

我正在尋找使用列名稱（而不是位置）從Filemaker中導出。目前我出口以下XSL樣式表，按位置輸出：

<?xml version="1.0" encoding="utf-8"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:fm="http://www.filemaker.com/fmpxmlresult" exclude-result-prefixes="fm" > 
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/> 
<xsl:template match="/"> 
    <people> 
    <xsl:for-each select="fm:FMPXMLRESULT/fm:RESULTSET/fm:ROW"> 
     <person> 
     <name> 
      <xsl:value-of select="fm:COL[01]/fm:DATA"/> 
     </name> 
     <location> 
      <xsl:value-of select="fm:COL[02]/fm:DATA"/> 
     </location> 
     </person> 
    </xsl:for-each> 
    </people> 
</xsl:template> 
</xsl:stylesheet> 

任何想法？謝謝。

Answer 1

如果你只想讓代碼更易讀，那麼我會建議簡單的東西，比如：

<!-- expected columns --> 
<xsl:variable name="NAME" value="1" /> 
<xsl:variable name="LOCATION" value="2" /> 
<!-- ... --> 
<people> 
    <xsl:for-each select="fm:FMPXMLRESULT/fm:RESULTSET/fm:ROW"> 
    <person> 
     <name> 
     <xsl:value-of select="fm:COL[$NAME]/fm:DATA"/> 
     </name> 
     <location> 
     <xsl:value-of select="fm:COL[$LOCATION]/fm:DATA"/> 
     </location> 
    </person> 
    </xsl:for-each> 
</people> 

BTW，與<xsl:value-of />可以省略fm:DATA，即使用：

<xsl:value-of select="fm:COL[$LOCATION] /> 

它會返回相同的結果。

如果您需要更復雜的東西，請解釋。

更新：

要通過列名更難引用列，但可能有這樣的事情：

<!-- Define a key to get a field and all fields that precede it by the field name --> 
<xsl:key name="N" match="/fm:FMPXMLRESULT/fm:METADATA/fm:FIELD" use="@NAME" /> 
<xsl:key name="N" match="/fm:FMPXMLRESULT/fm:METADATA/fm:FIELD" 
    use="following-sibling::fm:FIELD/@NAME" /> 
<!-- Then *count* them it in the code like that --> 
<people> 
    <xsl:for-each select="fm:FMPXMLRESULT/fm:RESULTSET/fm:ROW"> 
    <person> 
     <name> 
     <xsl:value-of select="fm:COL[count(key('N', 'name'))]" /> 
     </name> 
     <location> 
     <xsl:value-of select="fm:COL[count(key('N', 'location'))]" /> 
     </location> 
    </person> 
    </xsl:for-each> 
</people> 

並非完全優雅，但作品。