VB腳本 - 查找最近的文件夾，將文件複製到目標文件夾

Question

我正在尋找一種方法來查找最近的文件夾，將文件複製到目標文件夾。

Answer 1

試試這個：

rootFolder = "C:\root" 
dstFolder = "C:\dst" 

Set fso = CreateObject("Scripting.FileSystemObject") 

Set mostRecent = FindMostRecent(fso.GetFolder(rootFolder)) 
For Each f In mostRecent.Files 
    f.Copy fso.BuildPath(dstFolder, f.Name) 
Next 

Function FindMostRecent(fldr) 
    Set mrf = fldr 
    For Each sf In fldr.SubFolders 
    Set mrsf = FindMostRecent(sf) 
    If mrsf.DateLastModified > mrf.DateLastModified Then Set mrf = mrsf 
    Next 
    Set FindMostRecent = mrf 
End Function 

Answer 2

我看到你通過你的文件夾作爲參數時遇到一些困難。 Ansgar Wiechers的例子展示瞭如何用硬編碼值來做到這一點。爲了簡單起見，我們通常在我們的答案中進行。

rootFolder = "C:\root" 'target folder (where to search) 
dstFolder = "C:\dst"  'destionation (where to copy) 

但是，如果你更喜歡通過他們的動力像...

CScript my_task.vbs C:\root C:\dst 

...那麼這包括在您的.vbs文件的開頭：

With WScript.Arguments 
    If .Count < 2 Then WScript.Quit(-1) 
    rootFolder = .Item(0) 
    dstFolder = .Item(1) 
End With 

接下來，通過閱讀你的意見，在我看來，你只需要立即的子文件夾，如果是這樣，因爲批處理腳本不太好，我會做這樣的事情：

tmpFile = "result.txt" 'temp file 
With CreateObject("WScript.Shell") 
    .CurrentDirectory = rootFolder 
    .Run "CMD /C DIR /A:D /B /O:-D /T:C > " & tmpFile, 0, True 
    With CreateObject("Scripting.FileSystemObject") 
     With .OpenTextFile(tmpFile) 
      mostRecent = .ReadLine 
     End With 
     .GetFile(tmpFile).Delete 
    End With 
    .CurrentDirectory = mostRecent 
    .Run "CMD /C COPY *.* " & dstFolder, 0, False 
End With 

二手DIR開關：

/A:D = attributes Directory 
/B = bare format 
/O:-D = order by date/time (newly first) 
/O:D = order by date/time (oldest first) 
/T:C = sort by Creation 
/T:A = sort by Last Access 
/T:W = sort by Last Written