使用XSL轉換爲<br/> 1.0

鑑於XML：使用XSL轉換爲<br/> 1.0

<data> 
<field>Value 1&#xD;Value 2&#xD;Value 3&#xD;</field> 
</data>

我希望能夠創造一些HTML顯示值並轉換成<br/>

<html> 
<head/> 
<body> 
<div>Field Values</div> 
<div>Value 1<br/>Value 2<br/>Value 3<br/></div> 
</body> 
</html>

不過我想不到使用XSL版本1.0來做到這一點的方式？

我試圖

<xsl:value-of select="field" disable-output-escaping="yes"/>

但是所有文本1行顯示。

任何意見/建議嗎？

感謝

戴夫

來源

2010-06-23 CraftyFella

這裏是你如何與<br/>替代：

<xsl:template match="data"> 
    <xsl:call-template name="add-br"> 
    <xsl:with-param name="text" select="field" /> 
    </xsl:call-template> 
</xsl:template> 

<xsl:template name="add-br"> 
    <xsl:param name="text" select="."/> 
    <xsl:choose> 
    <xsl:when test="contains($text, '&#xD;')"> 
     <xsl:value-of select="substring-before($text, '&#xD;')"/> 
     <br/> 
     <xsl:call-template name="add-br"> 
     <xsl:with-param name="text" select="substring-after($text,'&#xD;')"/> 
     </xsl:call-template> 
    </xsl:when> 
    <xsl:otherwise> 
    <xsl:value-of select="$text"/> 
    </xsl:otherwise> 
    </xsl:choose> 
</xsl:template>

來源

2010-06-23 11:46:29

酷。。謝謝..只有1件事情..你需要添加With Param給調用templ在頂部吃..除此之外.. 100％的工作。 whooooooooop – CraftyFella 2010-06-23 12:04:46

它也可以在''with-param''下工作，因爲它在節點'data'內。 – 2010-06-23 12:16:51

您可以使用遞歸模板也做替換：

<?xml version="1.0" encoding="utf-8"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" indent="yes"/> 

    <xsl:template match="/"> 
     <data> 
     <xsl:call-template name="replaceCharsInString"> 
      <xsl:with-param name="stringIn" select="data/field" /> 
     </xsl:call-template> 
     </data> 
    </xsl:template> 

    <xsl:template name="replaceCharsInString"> 
    <xsl:param name="stringIn"/> 
    <xsl:choose> 
     <xsl:when test="contains($stringIn,'&#xD;')"> 
     <xsl:value-of select="substring-before($stringIn,'&#xD;')"/> 
     <br /> 
     <xsl:call-template name="replaceCharsInString"> 
      <xsl:with-param name="stringIn" 
          select="substring-after($stringIn,'&#xD;')"/> 
     </xsl:call-template> 
     </xsl:when> 
     <xsl:otherwise> 
     <xsl:value-of select="$stringIn"/> 
     </xsl:otherwise> 
    </xsl:choose> 
    </xsl:template> 
</xsl:stylesheet>

來源

2010-06-23 11:49:40

布里爾...謝謝 – CraftyFella 2010-06-23 12:05:39

使用XSL轉換 爲<br/> 1.0

回答

相關問題

使用XSL轉換爲<br/> 1.0