XSLT 1.0 - 創建節點集，並作爲參數傳遞

Question

使用XSLT 1.0，我想基本上創建一個小的節點集，然後將其作爲參數傳遞給模板，類似如下：

<xsl:call-template name="widget"> 
    <xsl:with-param name="flags"> 
    <items> 
     <item>widget.recent-posts.trim-length=100</item> 
     <item>widget.recent-posts.how-many=3</item> 
     <item>widget.recent-posts.show-excerpt</item> 
    </items> 
    </xsl:with-param> 
</xsl:call-template> 

的想法是，然後從widget模板中我可以寫這樣的：

<xsl:value-of select="$flags/item[1]" /> 

很顯然，我得到的編譯錯誤。我如何能實現這樣的事情？

Answer 1

有一個在XSLT 1.0的方式（非標）動態地創建臨時樹和他們評估XPath表達式，但是這需要使用xxx:node-set()功能。

每當節點被動態地一xsl:variable或xsl:param的身體內部產生，那xsl:variable/xsl:param類型是RTF（結果樹片段）和W3 XSLT 1.0規格。可以嚴格限制可以針對RTF評估的XPath表達式。

作爲一種變通方法，幾乎​​每XSLT 1.0廠商都有自己xxx:node-set()擴展函數，它接受一個RTF，併產生從它正常的節點集。

對於不同的供應商，xxx前綴（或您選擇的任何其他前綴）所綁定的名稱空間不同。對於MSXML和兩個.NET XSLT處理器，它是："urn:schemas-microsoft-com:xslt"。 EXSLT庫使用命名空間："http://exslt.org/common"。該名稱空間EXSLT在許多XSLT 1.0處理器上實現，如果可能，建議使用其xxx:node-set()擴展名。

下面是一個簡單的例子：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:msxsl="urn:schemas-microsoft-com:xslt" 
xmlns:ext="http://exslt.org/common" 
    exclude-result-prefixes="ext msxsl" 
> 
<xsl:template match="/"> 
    <xsl:variable name="vTempRTF"> 
    <a> 
    <b/> 
    </a> 
    </xsl:variable> 

    <xsl:copy-of select="ext:node-set($vTempRTF)/a/*"/> 
</xsl:template> 
</xsl:stylesheet> 

Answer 2

好吧，我設法解決這個問題的方式如下：

首先添加自定義空間，以你的樣式，例如xmlns:myns="http://my.ns.com"

然後定義節點集在樣式表的頂部：

<myns:recent-posts-flags> 
    <item>widget.recent-posts.trim-length=100</item> 
    <item>widget.recent-posts.how-many=3</item> 
    <item>widget.recent-posts.show-excerpt</item> 
</myns:recent-posts-flags> 

然後在下面的方式參考：

<xsl:call-template name="widget"> 
    <xsl:with-param name="flags" select="document('')/*/myns:recent-posts-flags" /> 
</xsl:call-template> 

這工作，但它仍然是非常適合我的定義在<xsl:with-param>標籤本身中的節點集，就像我給的第一個例子..任何人都認爲這將是可能的？