FPC：記錄上的RTTI

Question

這是我第一次在本網站上。通常，我在舊帖子中找到回覆沒有問題，但我沒有成功解決我的實際問題。

我想知道如何使用RTTI函數在運行時知道Lazarus/FPC下記錄的屬性/成員？我知道如何爲一個類（Tpersistent後裔和已發佈的屬性）而不是FPC。有些鏈接指出如​​何在德爾福（從D2010開始）下做到這一點，但我不知道如何在拉撒路之下進行轉置。

在此先感謝您的幫助和幫助。 Salim Larhrib。

凱文：正如我之前所說，這是我的第一個要求。但是我明白。你是對的。這是我的代碼

procedure TMainForm.btRecordTHashListClick(Sender: TObject); 
var 
    pTData : PTypeData; 
    pTInfo : PTypeInfo; 
    TablePtr : PatableRecord; 
    Loop  : Integer; 
begin 
    // Set of Record pointers + HashList 

    // Create Container 
    if not Assigned(FTableRecList) then FTableRecList := TFPHashList.Create; 

    // Insert data 
    new(TablePtr); 
    TablePtr^.description := 'Dictionnaire des tables.'; 
    FTableRecList.add('atable', TablePtr); 

    new(TablePtr); 
    TablePtr^.description := 'Dictionnaire des fonctions.'; 
    FTableRecList.add('afunction', TablePtr); 

    new(TablePtr); 
    TablePtr^.description := 'Dictionnaire des listes d''option.'; 
    FTableRecList.add('alist', TablePtr); 

    // Read records 
    for Loop:=0 to FTableRecList.Count-1 do 
    begin 
    TablePtr := FTableRecList[Loop]; 
    ShowMessage('Parcours Index : ' + TablePtr^.description); 
    end; 

    // Find records 
    try 
    TablePtr := FTableRecList.Find('ddafunction'); 
    ShowMessage('Record finded : ' + TablePtr^.description); 
    except 
    ShowMessage('Not such record .'); 
    end; 
    try 
    TablePtr := FTableRecList.Find('afunction'); 
    ShowMessage('Record finded : ' + TablePtr^.description); 
    except 
    ShowMessage('No such record.'); 
    end; 

    // Free memory : To put later in TFPHashList wrapper 
    for Loop:=0 to FTableRecList.Count-1 do Dispose(PatableRecord(FTableRecList[Loop])); 

// RTTI 
    pTInfo := TypeInfo(TatableRecord); 

    pTData := GetTypeData(pTInfo); 
    ShowMessage('Member count = '+IntToStr(pTData^.PropCount)); 
end; 

Answer 1

警告：它的工作原理與FPC 2.7.1或更高版本。

您可以使用指針處理記錄字段。下面是例子：

program rttitest; 

uses 
    TypInfo; 

type 
    TMyRec = record 
     p1: Integer; 
     p2: string; 
    end; 

var 
    td: PTypeData; 
    ti: PTypeInfo; 
    mf: PManagedField; 
    p: Pointer; 
    f: Pointer; 

    r: TMyRec; 

begin 
    r.p1 := 312; 
    r.p2 := 'foo-bar'; 

    ti := TypeInfo(r); 
    td := GetTypeData(ti); 

    Writeln(td^.ManagedFldCount); // Get count of record fields 

    // After ManagedFldCount TTypeData contains list of the TManagedField records 
    // So ... 
    p := @(td^.ManagedFldCount); // Point to the ManagedFldCount ... 
    // Inc(p, SizeOf(Integer)); // Skip it (Wrong for 64-bit targets) 
    // Next line works for both 
    Inc(p, SizeOf(td^.ManagedFldCount)); // Skip it 

    mf := p; // And now in the mf we have data about first record's field 
    Writeln(mf^.TypeRef^.Name); 

    Write(r.p1); // Current value 
    f := @r; 
    Inc(f, mf^.FldOffset); // Point to the first field 
    Integer(f^) := 645; // Set field value 
    Writeln(r.p1); // New value 

    // Repeat for the second field 
    Inc(p, SizeOf(TManagedField)); 
    mf := p; 
    Writeln(mf^.TypeRef^.Name); 

    Write(r.p2); 
    f := @r; 
    Inc(f, mf^.FldOffset); 
    string(f^) := 'abrakadabra'; 
    Writeln(r.p2); 


    Readln; 
end.