SQL SERVER sp_executesql的不正確的語法附近「）」

Question

我有，當我試圖在SQL Server中執行sp_executesql的2014 有我的存儲過程這個問題：

alter proc search 
@Name nvarchar 
as 
declare @SQL nvarchar 
declare @Params nvarchar 
begin 
    set @SQL = N' Select * from Table_1 , Table_2 where (1=1) ' 

    if @Name is not null 
     begin 
     set @SQL = @SQL + ' and Table_2.thatoneID = (Select Table_1.Id from Table_1 where Table_1.Name like ''%''+@Name+''%'') ' 
     end 
    set @SQL = @SQL + ' and Table_2.thatoneID = Table_1.Id ; ' 

    set @Params = '@Name nvarchar' 

    execute sp_executesql @SQL , @Params , @Name 
end 

當我想：

Execute search 'hh' 

我得到這個錯誤

Msg 102, Level 15, State 1, Line 29 Incorrect syntax near ')'. 

Answer 1

你應該總是指定長度Ø f變量，所以nvarchar（100），否則它只會默認爲1個字符。

只是測試你的變量都保存什麼用它們打印：

print @sql 
print @params 

由於沒有長度的設置，打印的唯一的事情就是

@ 

爲什麼只有「@」，而不是「S」來自SELECT關鍵字，爲@sql變量？因爲你在@sql變量的開頭有一個空格。

與之相對的每一個變量設置尺寸時，（我只是去，最大，因爲我不知道你真正需要什麼長度）來：

declare @SQL nvarchar(max) 
    , @Name nvarchar(max) 
declare @Params nvarchar(max) 
begin 
    set @SQL = N' Select * from Table_1 , Table_2 where (1=1) ' 

    if @Name is not null 
     begin 
     set @SQL = @SQL + ' and Table_2.thatoneID = (Select Table_1.Id from Table_1 where Table_1.Name like ''%''+@Name+''%'') ' 
     end 
    set @SQL = @SQL + ' and Table_2.thatoneID = Table_1.Id ; ' 

    set @Params = '@Name nvarchar' 

    print @sql 
    print @params 

end 

，這將給你：

Select * from Table_1 , Table_2 where (1=1) and Table_2.thatoneID = Table_1.Id ; 
@Name nvarchar 

我建議你先試試看看你是否仍然有錯誤。

Answer 2

起初 - 請使用table aliases。

二，重寫您的查詢，您正在使用old ANSI style。

第三 - 定義nvarchar大小。

第四 - 爲什麼你甚至使用動態SQL？

ALTER PROC search 
    @Name nvarchar(max) 
AS 

SELECT * 
FROM Table_1 t1 
INNER JOIN Table_2 t2 
    ON t2.thatoneID = t1.Id 
WHERE (1=1) AND t1.Name LIKE '%'+@Name+'%' 

如果您在使用動態SQL堅持，你可以使用這個：

ALTER PROC search 
    @Name nvarchar(max) 
AS 
DECLARE @SQL nvarchar(max), 
     @Params nvarchar(max) 

SELECT @SQL = N' 
SELECT * 
FROM Table_1 t1 
INNER JOIN Table_2 t2 
    ON t2.thatoneID = t1.Id 
WHERE (1=1) AND t1.Name LIKE ''%''+@Name+''%''' 

PRINT @sql 
SET @Params = '@Name nvarchar(max)' 

EXEC sp_executesql @SQL, @Params, @Name = @Name