更換XML文本

Question

我有一個包含以下標記一個XML文件：

<gmd:title> 
    <gco:CharacterString>READER FOREVER LEADER</gco:CharacterString> 
</gmd:title> 

我試圖替換標題：

<gmd:title> 
    <gco:CharacterString>CHANGE TITLE</gco:CharacterString> 
</gmd:title> 

但我只有這個代碼：

Set objXMLDoc = CreateObject("Microsoft.XMLDOM") 
objXMLDoc.async = False 
objXMLDoc.load("albums.xml") 
Set Elem = objXMLDoc.documentElement.selectSingleNode("gco:CharacterString") 
MsgBox(Elem.text) 

我如何能做到使用VBScript？

Answer 1

比一點點幫助更多的從the first hit for the obvious google search，我修改從here我的回答可以得到：

Dim oFS : Set oFS = CreateObject("Scripting.FileSystemObject") 
    Dim sFSpec : sFSpec = goFS.GetAbsolutePathName("..\testdata\xml\so15393560.xml") 
    Dim sNS : sNS  = "xmlns:gmd='urn:x:y:z:1' xmlns:gco='urn:x:y:z:1'" 
    Dim oXML : Set oXML = CreateObject("Msxml2.DOMDocument") 
    oXML.setProperty "SelectionLanguage", "XPath" 
    oXML.setProperty "SelectionNamespaces", sNS 
    oXML.async = False 
    oXML.load sFSpec 
    If 0 = oXML.parseError Then 
    WScript.Echo oXML.xml 
    WScript.Echo "-----------------" 
    Dim sXPath : sXPath = "/gmd:title/gco:CharacterString" 
    Dim ndFnd : Set ndFnd = oXML.selectSingleNode(sXPath) 
    If ndFnd Is Nothing Then 
     WScript.Echo sXPath, "not found" 
    Else 
     WScript.Echo ndFnd.text 
     WScript.Echo "-----------------" 
     ndFnd.text = "Abracadabra" 
     WScript.Echo oXML.xml 
    End If 
    Else 
    WScript.Echo oXML.parseError.reason 
    End If 

輸出：

<gmd:title xmlns:gmd="urn:x:y:z:1" xmlns:gco="urn:x:y:z:1"> 
     <gco:CharacterString>READER FOREVER LEADER</gco:CharacterString> 
</gmd:title> 

----------------- 
READER FOREVER LEADER 
----------------- 
<gmd:title xmlns:gmd="urn:x:y:z:1" xmlns:gco="urn:x:y:z:1"> 
     <gco:CharacterString>Abracadabra</gco:CharacterString> 
</gmd:title>