文件中使用最多的100個字符串

Question

如何使用Perl在.txt文件中找到最常用的100個字符串（單詞）？到目前爲止，我有以下內容：

use 5.012; 
use warnings; 

open(my $file, "<", "file.txt"); 

my %word_count; 
while (my $line = <$file>) { 
    foreach my $word (split ' ', $line) { 
    $word_count{$word}++; 
    } 
} 

for my $word (sort keys %word_count) { 
    print "'$word': $word_count{$word}\n"; 
} 

但是，這隻計算每個單詞，並按字母順序組織它。我想要文件中排名前100的最常用詞，按出現次數排序。有任何想法嗎？

相關：Count number of times string repeated in files perl

Answer 1

通過閱讀精細perlfaq4（1）手冊頁，一個學習how to sort hashes by value。所以試試這個。它比你的方法更習慣地「純粹」。

#!/usr/bin/env perl  
use v5.12; 
use strict; 
use warnings; 
use warnings FATAL => "utf8"; 
use open qw(:utf8 :std); 

my %seen; 
while (<>) { 
    $seen{$_}++ for split /\W+/; # or just split; 
} 

my $count = 0; 
for (sort { 
     $seen{$b} <=> $seen{$a} 
        || 
      lc($a) cmp lc($b) # XXX: should be v5.16's fc() instead 
        || 
       $a cmp $b 
    } keys %seen) 
{ 
    next unless /\w/; 
    printf "%-20s %5d\n", $_, $seen{$_}; 
    last if ++$count > 100; 
} 

當針對其自身運行中，第一線10輸出的是：

seen      6 
use      5 
_      3 
a      3 
b      3 
cmp      2 
count     2 
for      2 
lc      2 
my      2