從互聯網下載文件，同時能夠中止下載任何時間

Question

我想從我的Delphi程序下載一個文件在一個單獨的線程專用於下載。

問題是主程序可以隨時關閉（因此下載線程也可以隨時終止）。因此，即使沒有連接或服務器滯後寶貴的秒數，我也需要一種方法在一秒鐘或兩秒內終止下載線程。

你們推薦使用什麼功能？

我已經嘗試過使用InterOpenURL/InternetReadFile，但它沒有超時參數。它有一個異步版本，但我找不到任何工作的德爾福的例子，我不知道如果異步版本會保護我免受掛起...

使用套接字已被推薦給我之前，但TClientSocket doesn似乎也沒有超時功能。

我需要做好充分準備，所以如果用戶在他/她的計算機上有互聯網連接問題，或者網絡服務器保持滯後，我的應用程序在關閉之前不會掛起。

請記住，在回答我不想使用任何第三方組件或Indy。任何示例代碼非常感謝。

謝謝！

Answer 1

TWinSocketStream有超時。您基本上創建了一個阻塞套接字，然後使用該套接字創建一個TWinSocketStream進行讀/寫操作。 （有點像使用StreamWriter）。然後循環直到連接關閉，線程終止，或者達到期望的字節數。有一個WaitForData（）允許你檢查輸入數據是否超時，所以你永遠不會超過該超時值「鎖定」。

但是，你必須自己處理http進程。即發送'GET'，然後讀取響應頭以確定需要多少字節，但那不是太困難。

Answer 2

This Works。

var 
    DownloadAbort: boolean; 

procedure Download(const URL, FileName: string); 
var 
    hInet: HINTERNET; 
    hURL: HINTERNET; 
    Buffer: array[0..1023] of AnsiChar; 
    BufferLen, amt: cardinal; 
    f: file; 
const 
    UserAgent = 'Delphi Application'; // Change to whatever you wish 
begin 
    DownloadAbort := false; 
    hInet := InternetOpen(PChar(UserAgent), INTERNET_OPEN_TYPE_PRECONFIG, nil, nil, 0); 
    try 
    hURL := InternetOpenUrl(hInet, PChar(URL), nil, 0, 0, 0); 
    try 
     FileMode := fmOpenWrite; 
     AssignFile(f, FileName); 
     try 
     Rewrite(f, 1); 
     repeat 
      InternetReadFile(hURL, @Buffer, SizeOf(Buffer), BufferLen); 
      BlockWrite(f, Buffer[0], BufferLen, amt); 
      if DownloadAbort then 
      Exit; 
     until BufferLen = 0; 
     finally 
     CloseFile(f); 
     end; 
    finally 
     InternetCloseHandle(hURL); 
    end; 
    finally 
    InternetCloseHandle(hInet); 
    end; 
end; 

在實踐中，上面的代碼將是你的線程的Execute方法的一部分，而你並不需要DownloadAbort; intead，你檢查

if Terminated then 
    Exit; 

Answer 3

感謝GrandmasterB，這裏是我已經成功地放在一起碼：（這是在我的線程的執行塊）

var 
    Buffer: array [0..1024 - 1] of Char; 
    SocketStream: TWinSocketStream; 
    RequestString: String; 
    BytesRead: Integer; 
begin 
    try 
    ClientSocket.Active := true; 
    DownloadedData := ''; 
    FillChar(Buffer, SizeOf(Buffer), #0); 

    if not Terminated then 
    begin 
     // Wait 10 seconds 
     SocketStream := TWinSocketStream.Create(ClientSocket.Socket, 10000); 
     try 
     // Send the request to the webserver 
     RequestString := 'GET /remotedir/remotefile.html HTTP/1.0'#13#10 + 
      'Host: www.someexamplehost.com'#13#10#13#10; 
     SocketStream.Write(RequestString[1], Length(RequestString)); 

     // We keep waiting for the data for 5 seconds 
     if (not Terminated) and SocketStream.WaitForData(5000) then 
      repeat 
      // We store the data in our buffer 
      BytesRead := SocketStream.Read(Buffer, SizeOf(Buffer)); 

      if BytesRead = 0 then 
       break 
      else 
       DownloadedData := DownloadedData + Buffer; 
      until Terminated or (not SocketStream.WaitForData(2000)); 
     finally 
     // Close the connection 
     SocketStream.Free; 
     if ClientSocket.Active then 
      ClientSocket.Active := false; 
     end; 
    end; 
    except 
    end; 

你必須把這個線程的構造函數：

ClientSocket := TClientSocket.Create(nil); 
    ClientSocket.Host := 'www.someexamplehost.com'; 
    ClientSocket.Port := 80; 
    ClientSocket.ClientType := ctBlocking; 

    inherited Create(false); // CreateSuspended := false; 

這給desctructor：

ClientSocket.Free; 
    inherited; 

Answer 4

從delphi.about.com

uses ExtActns, ... 

type 
    TfrMain = class(TForm) 
    ... 
    private 
    procedure URL_OnDownloadProgress 
     (Sender: TDownLoadURL; 
     Progress, ProgressMax: Cardinal; 
     StatusCode: TURLDownloadStatus; 
     StatusText: String; var Cancel: Boolean) ; 
    ... 

implementation 
... 

procedure TfrMain.URL_OnDownloadProgress; 
begin 
    ProgressBar1.Max:= ProgressMax; 
    ProgressBar1.Position:= Progress; 
end; 

function DoDownload; 
begin 
    with TDownloadURL.Create(self) do 
    try 
    URL:='http://0.tqn.com/6/g/delphi/b/index.xml'; 
    FileName := 'c:\ADPHealines.xml'; 
    OnDownloadProgress := URL_OnDownloadProgress; 

    ExecuteTarget(nil) ; 
    finally 
    Free; 
    end; 
end; 

{ 注： URL屬性指向互聯網 FileName是本地文件 }