如何搜索和在Perl

Question

替換字符串的文件我輸入文件的內容如下：

abc\**def\ghi**\abc\!!!!! 
abc\**4nfiug\frgrefd\gtefe\wf4fs**\abc\df3gwddw 
abc\**eg4/refw**\abc\f3 

我需要更換任何字符串abc \ --------------\abc之間在我輸入文件，ABC\CBA

我曾嘗試類似下面得到了需要replaced.But我碰到困難的時候，我需要使用搜索和替換字符串：

my $string1 = qr/abc\W+([^a]+)/; 
my $string2 = map{/$string1/ => " "} @input_file; #the string that need to be replaced 
my $string3 = 'ABC\CBA' #string i that i want it to replace to 

s/$string2/$string3/g 

能任何人都可以幫忙嗎？提前致謝。

Answer 1

#!/usr/bin/perl 
use strict; 
use warnings; 

open my $fh,"<", "tryit.txt" or die $!; 

while (my $line = <$fh>) { 
    $line =~ s/(abc\\)(.*?)(\\abc)/$1ABC\\CBA$3/; 
    print $line; 
} 

給出以下與輸入數據。那是你在找什麼？

abc\ABC\CBA\abc\!!!!! 
abc\ABC\CBA\abc\df3gwddw 
abc\ABC\CBA\abc\f3 

Answer 2

如果您不想在默認變量$_操作替代，你必須使用=~操作：

#!/usr/bin/perl 
use warnings; 
use strict; 

my @input_file = split /\n/, <<'__EOF__'; 
abc\**def\ghi**\abc\!!!!! 
abc\**4nfiug\frgrefd\gtefe\wf4fs**\abc\df3gwddw 
abc\**eg4/refw**\abc\f3 
__EOF__ 

my $pattern = qr/abc\\.*\\abc/;  # pattern to be matched 
my $string2 = join "\n", @input_file; # the string that need to be replaced 
my $string3 = 'ABC\CBA';    # string i that i want it to replace to 

$string2 =~ s/$pattern/$string3/g; 
print $string2; 

Answer 3

一個班輪修復文件：

perl -plwe 's/abc\\\K.*(?=\\abc)/ABC\\CBA/' input.txt > output.txt 

或作爲腳本：

use strict; 
use warnings; 

while (<DATA>) { 
    s/abc\\\K.*(?=\\abc)/ABC\\CBA/; 
    print; 
} 

__DATA__ 
abc\**def\ghi**\abc\!!!!! 
abc\**4nfiug\frgrefd\gtefe\wf4fs**\abc\df3gwddw 
abc\**eg4/refw**\abc\f3 

\K（保留）escap e序列表示這些字符不會被刪除。同樣，前瞻斷言(?= ...)將保持這部分比賽。我以爲你只是想改變之間的字符。

而不是\K可以使用後視聲明：(?<=abc\\)。作爲個人偏好，我改用\K。

Answer 4

perl -i -pe's/this/that/g;' file1

Answer 5

要解決有關直接替換文件「inplace」中的文本的註釋，您可以使用-i開關進行單線程。在腳本中，您可以查看使用Tie::File，它允許讀寫文件行作爲數組中的（可變）元素。複製Mike/TLP的回答：

#!/usr/bin/perl 
use strict; 
use warnings; 

use Tie::File; 

tie my @file, "Tie::File", "tryit.txt" or die $!; 

# I think you have to use $_ here (done implicitly) 
while (@file) { 
    s/(abc\\)(.*?)(\\abc)/$1ABC\\CBA$3/; 
    print; 
}