在Perl中，如何獲取當前正在執行的代碼的目錄或路徑？

Question

如果我在某些庫代碼中，如何確定當前正在執行的代碼文件的路徑？我知道如何通過查看ARGV得到頂級 perl文件的路徑，但是如果我加載一個庫，那麼庫如何知道它位於哪個路徑？

Answer 1

__FILE__令牌會爲您提供包括文件名的完整路徑。您可以使用File::Spec將其分割成組件：

my ($volume, $directory, $file) = File::Spec->splitpath(__FILE__); 

Answer 2

的所有庫包括通過use或require產生特殊%INC散列的條目。 （見perlvar）。

例如：

use strict; 
use warnings; 

use Data::Dumper; 

print Dumper \%INC; 

這將產生類似於下面的輸出：

$VAR1 = { 
     'warnings/register.pm' => '/usr/lib/perl5/5.8.8/warnings/register.pm', 
     'bytes.pm' => '/usr/lib/perl5/5.8.8/bytes.pm', 
     'XSLoader.pm' => '/usr/lib64/perl5/5.8.8/x86_64-linux-thread-multi/XSLoader.pm', 
     'Carp.pm' => '/usr/lib/perl5/5.8.8/Carp.pm', 
     'Exporter.pm' => '/usr/lib/perl5/5.8.8/Exporter.pm', 
     'strict.pm' => '/usr/lib/perl5/5.8.8/strict.pm', 
     'warnings.pm' => '/usr/lib/perl5/5.8.8/warnings.pm', 
     'overload.pm' => '/usr/lib/perl5/5.8.8/overload.pm', 
     'Data/Dumper.pm' => '/usr/lib64/perl5/5.8.8/x86_64-linux-thread-multi/Data/Dumper.pm' 
    }; 

此外，還有一個通用__FILE__常數將返回當前的文件名。 （另請參閱__PACKAGE__）。

Answer 3

找到文件名當期可執行的最簡單的方法是FindBin：

use FindBin; 
use File::Spec; 

print "the directory of my script is: " . $FindBin::Bin . "\n"; 
print "the base name of my script is: " . $FindBin::Script . "\n"; 
print "the canonical location of my script is: " . File::Spec->catfile($FindBin::Bin, $FindBin::Script) . "\n"; 

內部，您可以通過查看$0（腳本的名稱在一些信息得到儘可能調用在命令行）和__FILE__，這是當前正在執行的文件的名稱。 （見perldoc perlvar。）

要提取文件名當前執行的模塊的，開始檢查__PACKAGE__，做一些替代的魔法，然後查找文件名中%INC：

(my $filename = __PACKAGE__) =~ s#::#/#g; 
$filename .= '.pm'; 
my $abs_filename = $INC{$filename}; 

我這樣做在我的一個初始化庫中找到相對於當前模塊的路徑中的配置腳本（我有幾個代碼分支並排安裝，每個都有略微不同的配置）：

# use the location of the current module as a guide for where to find configs 
(my $filename = __PACKAGE__) =~ s#::#/#g; 
$filename .= '.pm'; 

(my $path = $INC{$filename}) =~ s#/\Q$filename\E$##g; # strip/and filename 
my $abs_config_file = File::Spec->catfile($path, $config_file); 
MyApp->initialize($abs_config_file); 

Answer 4

這是我通常用來獲取執行代碼路徑的代碼片段。

use Cwd qw/abs_path/; 
my ($real_path) = abs_path($0) =~ m/(.*)myscript.pl/i; 

這將實際的目錄路徑放到$ real_path中。在此之後，我通常也會執行chdir $real_path，以確保我的代碼實際上正在處理它應該是的目錄（通常在我使用Win32 :: Daemon編寫Windows服務時）。

我導出的abs_path子例程給出了作爲參數提供的任何文件（名稱/句柄）的路徑。在這種情況下，我提供了$0這是正在執行的Perl腳本的名稱。

我建議在Cpan上檢查Cwd以獲取更多指導。

Answer 5

最簡單的方法：

print $ENV{'PWD'};