如何使用xpath替換xml中的第一個節點屬性值

Question

在下面的XML中，需要使用XPath替換名稱空間。

<application xmlns="http://ns.adobe.com/air/application/4.0"> 
    <child id="1"></child> 
    <child id="2"></child> 
</application> 

我試着用

/application/@xmlns 

和

/*[local-name()='application']/@[local-name()='xmlns'] 

雙方未能給予的願望輸出。爲了替換文本，我使用了xmltask替換。

<xmltask source="${temp.file1}" dest="${temp.file1}"> 
    <replace path="/application/@xmlns" withText="http://ns.adobe.com/air/application/16.0" /> 
</xmltask> 

Answer 1

問題是xmlns不是屬性。您無法使用XPath進行選擇。

命名空間是節點名稱的一部分在XML：<foo xmlns="urn:foo-namespace" />和<foo xmlns="urn:bar-namespace" />是不兩次與相同的名稱和不同的屬性節點，它們是具有不同名稱的兩個節點和沒有屬性。

如果要更改命名空間，則必須構造一個全新的節點。

XSLT是更好的適合於這項任務：

<!-- update-air-ns.xsl --> 
<xsl:transform 
    version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:air4="http://ns.adobe.com/air/application/4.0" 
    xmlns="http://ns.adobe.com/air/application/16.0" 
> 
    <xsl:output method="xml" encoding="UTF-8" indent="yes" /> 

    <xsl:template match="@*|node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*|node()"/> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="air4:*"> 
     <xsl:element name="{local-name()}"> 
      <xsl:apply-templates select="@*|node()"/> 
     </xsl:element> 
    </xsl:template> 
</xsl:transform> 

這XSLT轉換做了兩兩件事：

• 第一模板（身份模板）遞歸複製節點，除非有更好的匹配給定節點的模板
• 第二個模板匹配air4名稱空間中的元素，並構造具有相同本地名稱但名稱空間不同的新元素。發生這種情況是因爲XSLT中的默認名稱空間聲明。所有新構造的元素都使用http://ns.adobe.com/air/application/16.0命名空間。

應用到您輸入XML，結果是

<application xmlns="http://ns.adobe.com/air/application/16.0"> 
    <child id="1"/> 
    <child id="2"/> 
</application> 

您可以使用Ant的XSLT任務：

<xslt in="${temp.file1}" out="${temp.file1}" style="update-air-ns.xsl" />