使用REPEAT塊直到事件發生？

Question

這是我的問題： 在啓動按鈕的觸發器上我想執行一個模塊。當我按下STOP按鈕時，它應該停止執行。在啓動按鈕的TRIGER

如 ：

REPEAT: 
    message "hai". 
END. 

，當我按下停止按鈕應該停止。我應該給REPEAT塊添加什麼額外的條件？最好我不想在停止按鈕Triger中寫入條件。請給出建議。

Answer 1

進度不是多線程的。

所以你必須仔細考慮通過哪些代碼段需要在什麼情況下執行以僞造它。 （比我最初的「無法完成」的迴應更仔細。）

由於「firhang」指出「PROCESS EVENTS」可用於檢查排隊的事件並準備好執行操作。

因此，您可以在事件處理程序中運行循環並讓該事件處理程序監聽其他事件。

我認爲有以下滿足原來的問題和工作在GUI和性格的客戶：

define variable i as integer no-undo. 

define variable bStop as logical no-undo. 

define button butStart label "Start". 
define button butStop label "Stop". 

form butStart butStop with frame but-frame row 1. 

on choose of butStop bStop = true. 

on choose of butStart do: 

    bStop = false. 

    do while bStop = false: 
    i = i + 1. 
    process events. 
    message i. 
    end. 

    message "Paused". 

end. 

enable butStart butStop with frame but-frame. 

pause 0 before-hide. 

wait-for window-close of current-window. 

Answer 2

DEFINE VARIABLE bStop AS LOGICAL NO-UNDO. 

DEFINE BUTTON butStop LABEL "Stop". 

FORM butStop WITH FRAME but-frame ROW 1. 

ON CHOOSE OF butStop bStop = TRUE. 

ENABLE butStop WITH FRAME but-frame. 

REPEAT: 
    PROCESS EVENTS. 
    MESSAGE "hai". 
    IF bStop THEN LEAVE. 
END. 

MESSAGE "stoped". 

WAIT-FOR WINDOW-CLOSE OF CURRENT-WINDOW. 

Answer 3

處理事件聲明 處理所有重要事件而不阻塞用戶輸入。

語法

處理事件

例 在您選擇停止此過程計數到1000：

R-proevs.p

DEFINE VARIABLE ix  AS INTEGER NO-UNDO. 
DEFINE VARIABLE stop-sel AS LOGICAL NO-UNDO. 
DEFINE BUTTON stop-it LABEL "STOP". 
DISPLAY stop-it. 
ON CHOOSE OF stop-it 
    stop-sel = TRUE. 
ENABLE stop-it. 
DO ix = 1 TO 1000: 
    DISPLAY ix VIEW-AS TEXT. 
    PROCESS EVENTS. 
    IF stop-sel THEN LEAVE. 
END. 

在每次通過循環，該過程顯示ix的新值，然後檢查是否有任何事件正在等待處理。如果沒有事件發生，則繼續執行並循環迭代。如果選擇了STOP按鈕，則會更改stop-sel的值來處理該事件。當執行繼續時，程序退出循環。

如果循環不包含PROCESS EVENTS語句，那麼choose事件不會處理，循環迭代直到ix等於1,000。

註釋 WAIT-FOR語句處理所有未決事件並阻止所有其他執行，直到發生指定事件。 PROCESS EVENTS語句處理所有未決事件，並立即繼續執行下一個語句。 如果有任何已收到PROCEDURE-COMPLETE事件但尚未處理的異步請求，則此語句按WAIT-FOR語句所述處理這些事件。 您無法在ABL中調用.NET方法system.Windows.Forms.Application：DoEvent（）。 PROCESS EVENTS語句執行此方法的功能。 當執行此語句時，.NET會在ABL會話的上下文中引發異常。