檢查用戶選擇的範圍或取消

Question

我有以下代碼，提示用戶選擇一個範圍的單元格。

我很難檢查範圍是否有效（即他們是否只是在輸入框中輸入數字？），或者他們是否按下取消。我如何區分？

Do While (True)  
    Dim mInput As Range 
    mInput = Application.InputBox(Prompt:="Please select the cells.", Type:=8) 
    If (mInput Is Nothing) Then 
     Exit Sub 
    End If 

    If (mInputRange.Columns.Count <> 1) Then 
     MsgBox "There must be only one column selected.", vbOKOnly 
    Else 

    End If 

Loop 

Answer 1

如果Excel無法將其轉換爲範圍，則在返回結果之前返回錯誤。嘗試自己做。

而且，我相信你已經這樣做，但你需要使用

set mInput = Application.InputBox(Prompt:="Please select the cells.", Type:=8) 

，而不是

mInput = Application.InputBox(Prompt:="Please select the cells.", Type:=8) 

如果按取消錯誤也上升，這意味着你需要以使用某種錯誤檢查程序：

Sub test() 

    On Error GoTo handler 

    Dim rng As Range 

    Set rng = Application.InputBox("a", Type:=8) 

    Debug.Print rng.Address 

    Exit Sub 

handler: 
    Select Case Err.Number 
     Case 424 
      MsgBox "Cancelled.", vbOKOnly + vbInformation, "Cancellation dialog" 
     Case Else 
      Err.Raise Err.Number, Err.Source, Err.Description, Err.HelpFile, Err.HelpContext 
    End Select 

End Sub 

Answer 2

雖然mkingston的代碼確實有效（我upvoted），我認爲最好測試Nothing然後恢復到錯誤處理程序。然後，該代碼可以流動到行動，或採取另一種路徑，而不是需要重新開始後的錯誤處理（這我保留了無法預料的問題）

Sub test() 
Dim rng As Range 
On Error Resume Next 
Set rng = Application.InputBox("Please select the cells", Type:=8) 
On Error GoTo 0 
If Not rng Is Nothing Then 
    If rng.Columns.Count <> 1 Then 
     MsgBox "There must be only one column selected.", vbOKOnly 
    Else 
     'do stuff 
    End If 
Else 
    MsgBox "User either cancelled range selected or selected an invalid range", vbCritical 
End If 
End Sub