無法獲取msconfig.exe在system32文件夾中運行德爾福

Question

我在Win 7 64b上運行。 我試圖從我的delphi應用程序運行msconfig。 msconfig.exe文件位於system32文件夾中。 我將msconfig.exe複製到c：\中，效果很好。 這看起來像某種權限問題。

var 
errorcode: integer; 
begin 
    errorcode := 
ShellExecute(0, 'open', pchar('C:\Windows\System\msconfig.exe'), nil, nil, SW_NORMAL); 
if errorcode <= 32 then 
ShowMessage(SysErrorMessage(errorcode)); 
end; 

有沒有人看到這個，並想出瞭如何從sys32運行msconfig.exe。

Answer 1

此行爲是由File System Redirector作爲解決方法，您可以使用Wow64DisableWow64FsRedirection和Wow64EnableWow64FsRedirection功能。

{$APPTYPE CONSOLE} 


uses 
    ShellAPi, 
    SysUtils; 

Function Wow64DisableWow64FsRedirection(Var Wow64FsEnableRedirection: LongBool): LongBool; StdCall; 
    External 'Kernel32.dll' Name 'Wow64DisableWow64FsRedirection'; 
Function Wow64EnableWow64FsRedirection(Wow64FsEnableRedirection: LongBool): LongBool; StdCall; 
    External 'Kernel32.dll' Name 'Wow64EnableWow64FsRedirection'; 


Var 
    Wow64FsEnableRedirection: LongBool; 

begin 
    try 
    Wow64DisableWow64FsRedirection(Wow64FsEnableRedirection); 
    ShellExecute(0, nil, PChar('C:\Windows\System32\msconfig.exe'), nil, nil, 0); 
    Wow64EnableWow64FsRedirection(Wow64FsEnableRedirection); 
    except 
    on E: Exception do 
     Writeln(E.ClassName, ': ', E.Message); 
    end; 
end. 

Answer 2

如果您正在構建一個32位Delphi應用程序，那麼當它運行在64位Windows上時，System32文件夾實際上會被重新映射。對於32位應用程序，System32實際上是SysWOW64。因爲你從Explorer或cmd.exe在System32中「看到」它是因爲那些是64位進程。 在這種情況下，32位進程無法「看見」實際的64位System32文件夾。

一個解決方案是獲得支持64位定位和構建64位版本的最新Delphi。

Answer 3

從一個32位的過程中，你應該使用特殊的「SysNative」的別名，而不是「System32" 下文件夾直​​接訪問64位的系統文件夾：

PChar('C:\Windows\SysNative\msconfig.exe') 

如果您需要支持32位操作系統版本或64位編譯，使用IsWow64Process()來檢測，如果您的應用程序下運行的WOW64：

{$IFDEF WIN64} 
function IsWow64: Boolean; 
begin 
    Result := False; 
end; 
{$ELSE} 
function IsWow64Process(hProcess: THandle; out Wow64Process: BOOL): BOOL; stdcall; external 'kernel32.dll' delayed; 

function IsWow64: Boolean; 
var 
    Ret: BOOL; 
begin 
    Result := False; 
    // XP = v5.1 
    if (Win32MajorVersion > 5) or 
    ((Win32MajorVersion = 5) and (Win32MinorVersion >= 1)) then 
    begin 
    if IsWow64Process(GetCurrentProcess(), Ret) then 
     Result := Ret <> 0; 
    end; 
end; 
{$ENDIF} 

var 
    errorcode: integer; 
    SysFolder: string; 
begin 
    If IsWow64 then 
    SysFolder := 'SysNative' 
    else 
    SysFolder := 'System32'; 
  errorcode := ShellExecute(0, 'open', PChar('C:\Windows\'+SysFolder'+\msconfig.exe'), nil, nil, SW_NORMAL); 
    if errorcode <= 32 then 
    ShowMessage(SysErrorMessage(errorcode)); 
end;