尋求抽出文本，並自動特殊字符轉義

Question

例如，我想抽出hello/world並粘貼成hello/world

我試過唬弄的其他實例進行搜索，然後鍵入/\v ctr-r 0，並在搜索欄放置整個hello/world但實際上，它只搜索hello。

有沒有辦法在粘貼過程中自動轉義特殊字符？

Answer 1

添加此到vimrc文件讓您直觀地選擇一些東西，按*鍵，它會用轉義字符

vnoremap <silent> * :<C-U> 
    \let old_reg=getreg('"')<Bar>let old_regtype=getregtype('"')<CR> 
    \gvy/<C-R><C-R>=substitute(
    \escape(@", '/\.*$^~['), '\_s\+', '\\_s\\+', 'g')<CR><CR> 
    \gV:call setreg('"', old_reg, old_regtype)<CR> 
vnoremap <silent> # :<C-U> 
    \let old_reg=getreg('"')<Bar>let old_regtype=getregtype('"')<CR> 
    \gvy?<C-R><C-R>=substitute(
    \escape(@", '?\.*$^~['), '\_s\+', '\\_s\\+', 'g')<CR><CR> 
    \gV:call setreg('"', old_reg, old_regtype)<CR> 

source

Answer 2

搜索您可能會感興趣的：

" return a representation of the selected text 
" suitable for use as a search pattern 
function GetVisualSelection() 
    let old_reg = @a 
    normal! gv"ay 
    let raw_search = @a 
    let @a = old_reg 
    return substitute(escape(raw_search, '\/.*$^~[]'), "\n", '\\n', "g") 
endfunction 

xnoremap <leader>r :<C-u>%s/<C-r>=GetVisualSelection()<CR>/ 

它或多或少採用了與上述相同的策略，但採用稍微清潔且可重用的方式。

1. 選擇hello/world。
2. Hit <leader>r。
3. 命令行填充了:%s/hello\/world/，隨時爲您...
5. 型替換文本和......打<CR>。