只搜索並替換全文

Question

我正在尋找一種方法來搜索和替換整個單詞。因爲在我的情況下，整個單詞不僅可以用空格隔開，而且......，/？等我想不出一種有效的方式來編碼。

基本上，我希望做這樣的事情

replace([address], ***--list of separators, like .,;:/?--*** & [replacewhat] & ***--list of separators, like .,;:/?--*** ," " & [replacewith] & " ") 

我不知道如何來一次，而不是運行一次分離的每個組合替換功能通過分離器的列表（其中合併與我替換的300個單詞將相當於一個瘋狂的查詢數量）

Answer 1

您可以使用\b標記（用於單詞邊界）的模式在您希望的單詞前後進行正則表達式替換更換。

Public Function RegExpReplaceWord(ByVal strSource As String, _ 
    ByVal strFind As String, _ 
    ByVal strReplace As String) As String 
' Purpose : replace [strFind] with [strReplace] in [strSource] 
' Comment : [strFind] can be plain text or a regexp pattern; 
'    all occurences of [strFind] are replaced 
    ' early binding requires reference to Microsoft VBScript 
    ' Regular Expressions: 
    'Dim re As RegExp 
    'Set re = New RegExp 
    ' with late binding, no reference needed: 
    Dim re As Object 
    Set re = CreateObject("VBScript.RegExp") 

    re.Global = True 
    're.IgnoreCase = True ' <-- case insensitve 
    re.pattern = "\b" & strFind & "\b" 
    RegExpReplaceWord = re.Replace(strSource, strReplace) 
    Set re = Nothing 
End Function 

書面，搜索是區分大小寫的。如果你想不區分大小寫，使這條線：

re.IgnoreCase = True 

在立即窗口...

? RegExpReplaceWord("one too three", "too", "two") 
one two three 
? RegExpReplaceWord("one tool three", "too", "two") 
one tool three 
? RegExpReplaceWord("one too() three", "too", "two") 
one two() three 
? RegExpReplaceWord("one too three", "to", "two") 
one too three 
? RegExpReplaceWord("one too three", "t..", "two") 
one two three 

...併爲您的分隔符的範圍......

? RegExpReplaceWord("one.too.three", "too", "two") 
one.two.three 
? RegExpReplaceWord("one,too,three", "too", "two") 
one,two,three 
? RegExpReplaceWord("one;too;three", "too", "two") 
one;two;three 
? RegExpReplaceWord("one:too:three", "too", "two") 
one:two:three 
? RegExpReplaceWord("one/too/three", "too", "two") 
one/two/three 
? RegExpReplaceWord("one?too?three", "too", "two") 
one?two?three 
? RegExpReplaceWord("one--too--three", "too", "two") 
one--two--three 
? RegExpReplaceWord("one***too***three", "too", "two") 
one***two***three