如何在Unix中打印文件中的特定行？

Question

我想在Unix中打印來自文本文件的某些行。要打印的行號列在另一個文本文件中（每行一個）。

有沒有一個快速的方法來做到這一點與Perl或shell腳本？

Answer 1

假設行號要打印的排序。

open my $fh, '<', 'line_numbers' or die $!; 
my @ln = <$fh>; 
open my $tx, '<', 'text_file' or die $!; 
foreach my $ln (@ln) { 
    my $line; 
    do { 
    $line = <$tx>; 
    } until $. == $ln and defined $line; 
    print $line if defined $line; 
} 

Answer 2

我不會和大文件做這種方式，但（未經測試）：

open(my $fh1, "<", "line_number_file.txt") or die "Err: $!"; 
chomp(my @line_numbers = <$fh1>); 
$_-- for @line_numbers; 
close $fh1; 

open(my $fh2, "<", "text_file.txt") or die "Err: $!"; 
my @lines = <$fh2>; 

print @lines[@line_numbers]; 
close $fh2; 

Answer 3

$ cat numbers 
1 
4 
6 
$ cat file 
one 
two 
three 
four 
five 
six 
seven 
$ awk 'FNR==NR{num[$1];next}(FNR in num)' numbers file 
one 
four 
six 

Answer 4

我會做這樣的：

#!/bin/bash 
numbersfile=numbers 
datafile=data 

while read lineno < $numbersfile; do 
    sed -n "${lineno}p" datafile 
done 

下行到我的做法是，將產生大量的流程，這樣它會比其他選擇更慢。儘管它可讀性更高。

Answer 5

只需在基本while(<>)塊的上下文內使用eof，就可以避免其他一些答案（對排序行的要求）的限制。這會告訴你何時停止讀取行號並開始讀取數據。請注意，您需要在發生切換時重置$.。

# Usage: perl script.pl LINE_NUMS_FILE DATA_FILE 

use strict; 
use warnings; 

my %keep; 
my $reading_line_nums = 1; 

while (<>){ 
    if ($reading_line_nums){ 
     chomp; 
     $keep{$_} = 1; 
     $reading_line_nums = $. = 0 if eof; 
    } 
    else { 
     print if exists $keep{$.};  
    } 
} 

Answer 6

這是使用bash短溶液和sed

sed -n -e "$(cat num |sed 's/$/p/')" file 

其中num是數字的文件和文件（測試OS/X雪豹）輸入文件

$ cat num 
1 
3 
5 

$ cat file 
Line One 
Line Two 
Line Three 
Line Four 
Line Five 

$ sed -n -e "$(cat num |sed 's/$/p/')" file 
Line One 
Line Three 
Line Five 

Answer 7

cat -n foo |加入foo2 - |切-d」「-f2-

其中foo是用線將文件打印和foo2的是你的行號的文件

Answer 8

$ cat input 
every 
good 
bird 
does 
fly 

$ cat lines 
2 
4 

$ perl -ne 'BEGIN{($a,$b) = `cat lines`} print if $.==$a .. $.==$b' input 
good 
bird 
does

如果這是太多了一行代碼，使用

#! /usr/bin/perl 

use warnings; 
use strict; 

sub start_stop { 
    my($path) = @_; 
    open my $fh, "<", $path 
    or die "$0: open $path: $!"; 

    local $/; 
    return ($1,$2) if <$fh> =~ /\s*(\d+)\s*(\d+)/; 
    die "$0: $path: could not find start and stop line numbers"; 
} 

my($start,$stop) = start_stop "lines"; 

while (<>) { 
    print if $. == $start .. $. == $stop; 
} 

Perl的魔力開放允許創新的可能性，如

$ ./lines-between 'tac lines-between|' 
    print if $. == $start .. $. == $stop; 
while (<>) { 

Answer 9

這裏是一個辦法做到這一點在Perl沒有slurpin克任何從而程序的內存佔用量是獨立於文件的大小的（但是它假定要被打印的行號被排序）：

#!/usr/bin/perl 

use strict; use warnings; 
use autodie; 

@ARGV == 2 
    or die "Supply src_file and filter_file as arguments\n"; 

my ($src_file, $filter_file) = @ARGV; 

open my $src_h, '<', $src_file; 
open my $filter_h, '<', $filter_file; 

my $to_print = <$filter_h>; 

while (my $src_line = <$src_h>) { 
    last unless defined $to_print; 
    if ($. == $to_print) { 
     print $src_line; 
     $to_print = <$filter_h>; 
    } 
} 

close $filter_h; 
close $src_h; 

生成源文件：

C:\> perl -le "print for aa .. zz" > src

生成過濾器文件：

C:\> perl -le "print for grep { rand > 0.75 } 1 .. 52" > filter

C:\> cat filter 
4 
6 
10 
12 
13 
19 
23 
24 
28 
44 
49 
50

輸出：

C:\> f src filter 
ad 
af 
aj 
al 
am 
as 
aw 
ax 
bb 
br 
bw 
bx

爲了對付一個未排序的過濾器文件，你可以修改while循環：

while (my $src_line = <$src_h>) { 
    last unless defined $to_print; 
    if ($. > $to_print) { 
     seek $src_h, 0, 0; 
     $. = 0; 
    } 
    if ($. == $to_print) { 
     print $src_line; 
     $to_print = <$filter_h>; 
    } 
} 

如果過濾器文件的內容是相當隨機的，因爲它會保持復卷這會浪費大量的時間到源文件的開頭。在這種情況下，我會建議使用Tie::File。

Answer 10

這裏是一個辦法做到這一點使用Tie::File：

#!/usr/bin/perl 

use strict; use warnings; 
use autodie; 
use Tie::File; 

@ARGV == 2 
    or die "Supply src_file and filter_file as arguments\n"; 

my ($src_file, $filter_file) = @ARGV; 

tie my @source, 'Tie::File', $src_file, autochomp => 0 
    or die "Cannot tie source '$src_file': $!"; 

open my $filter_h, '<', $filter_file; 

while (my $to_print = <$filter_h>) { 
    print $source[$to_print - 1]; 
} 

close $filter_h; 

untie @source;