Perl程序利用最新登錄

Question

我在log.txt文件一個日誌文件，我想排序與最新的登錄用戶名

例 - 如果用戶保羅2個登錄一月和一個登錄二月份應採取 二月的登錄信息（至於保羅最後一次登錄）

輸入文件：log.txt--

Administrator-25/02/2013 
Administrator-26/03/2013 

輸出FILE-

Administrator-26/03/2013 

Answer 1

如果您可以將日期轉換爲ISO格式，則可以使用簡單的字符串比較。請參閱xkcd on ISO 8601。

#!/usr/bin/perl 
use warnings; 
use strict; 

sub later { 
    my @dates = @_; 
    for my $date (@dates) { 
     $date = join '/', (split m(/), $date)[2, 1, 0]; # Fix StackOverflow's syntax highlighting:/
    } 
    return $dates[0] lt $dates[1]; 
} 

my @lines = qw(Administrator-25/02/2013 
       Administrator-26/03/2013 
       Guest-01/01/2012 
       Administrator-01/01/2012 
      ); 

my $user = 'Administrator'; 
my $last = q(); 

for my $line (@lines) { 
    next unless 0 == index $line, "$user-"; 
    my $date = (split /-/, $line, 2)[1]; 
    $last = $date if later($last, $date) 
} 

print "$last\n"; 

Answer 2

爲微超長一個襯墊

perl -F\- -l -a -n -e ' $d=join(q(/),reverse split(q(/), $F[1])); $l{$F[0]}=$d if (!exists($l{$F[0]}) || $l{$F[0]} lt $d); END{ for (sort keys(%l)) { $v=$l{$_}; print "$_-",$l{$_} }}' logfile.txt 

自動分割上 - 並填充基於最大日哈希

輸出是「反向」日期順序因爲這是我用什麼比較

Answer 3

使用Unix時間比較日期：

#!/usr/bin/perl 
use strict; 
use warnings; 
use POSIX qw(mktime); 
$\="\n"; 

open my $fh, '<','log.txt' or die $!; 
my %h1; 
while(<$fh>){ 
     chomp; 
     my ($user,$date,$mon,$year)=split(/[\/-]/); #Split record 
     my $tm=mktime(0,0,0,$date,$mon-1,$year-1900); # Calculate the epoch 
     if (!exists$h1{$user} or ($h1{$user}<$tm)){ # store the bigger value in hash with the use as the key 
       $h1{$user}=$tm; 
     } 
} 
# Sort the hash on the basis of the key and print it 
foreach my $k (sort keys%h1){ 
     my @val=localtime($h1{$k}); 

     $val[4]+=1; 
     $val[5]+=1900; 
     print $k,'-',join "/",@val[3..5]; 
} 

輸入文件（log.txt的）：

Administrator-25/02/2013 
Administrator-26/03/2013 
Administrator-27/02/2013 
xyz-31/01/2013 
xyz-31/03/2013 

在運行該腳本：

xyz-31/3/2013 
Administrator-26/3/2013