文本文件在德爾福的書寫表演

Question

我軟處理傳入的字符串（來自Telnet或HTTP或...），並且我必須用Delphi XE2編寫文本文件才能處理字符串。由於有時字符串可能會導致程序崩潰，因此我需要確保在我的文件中包含字符串。所以我打開/關閉每個傳入的字符串的文件，我有一些性能問題。通常（對於我的代碼測試）8秒

我的代碼在這裏，有沒有辦法來改善保持函數的perfs？ （用於測試只需創建一個帶按鈕的表單：Button1，帶有OnClick事件& a Label：lbl1）。

Procedure AddToFile(Source: string; FileName :String); 
var 
    FText : Text; 
    TmpBuf: array[word] of byte; 
Begin 
    {$I-} 
    AssignFile(FText, FileName); 
    Append(FText); 
    SetTextBuf(FText, TmpBuf); 
    Writeln(FText, Source); 
    CloseFile(FText); 
    {$I+} 
end; 

procedure initF(FileName : string); 
Var FText : text; 
begin 
    {$I-} 
    if FileExists(FileName) then DeleteFile(FileName); 
    AssignFile(FText, FileName); 
    ReWrite(FText); 
    CloseFile(FText); 
    {$I+} 
end; 

procedure TForm1.Button1Click(Sender: TObject); 
var tTime : TDateTime; 
    iBcl : Integer; 
    FileName : string; 
begin 
    FileName := 'c:\Test.txt'; 
    lbl1.Caption := 'Go->' + FileName; lbl1.Refresh; 
    initF(FileName); 
    tTime := Now; 
    For iBcl := 0 to 2000 do 
    AddToFile(IntToStr(ibcl) + ' ' + 'lkjlkjlkjlkjlkjlkjlkj' , FileName); 
    lbl1.Caption := FormatDateTime('sss:zzz',Now-tTime); 
end; 

Answer 1

使用自動緩衝的TStreamWriter，並且可以自動處理將其緩衝區刷新爲TFileStream。它還允許您選擇追加到現有文件（如果需要），爲Unicode支持設置字符編碼，並允許您在其各種重載Create構造函數中設置不同的緩衝區大小（默認值爲1024字節或1K）。

（請注意，沖洗TStreamWriter只有TStreamBuffer的內容寫入TFileStream;它不刷新操作系統的文件系統緩存，所以文件實際上並未寫入磁盤，直到TFileStream被釋放。）

不要每次都創建StreamWriter;剛剛創建，一旦打開它，並在年底關閉它：

function InitLog(const FileName: string): TStreamWriter; 
begin 
    Result := TStreamWriter.Create(FileName, True); 
    Result.AutoFlush := True;   // Flush automatically after write 
    Result.NewLine := sLineBreak;  // Use system line breaks 
end; 

procedure CloseLog(const StreamWriter: TStreamWriter); 
begin 
    StreamWriter.Free; 
end; 

procedure TForm1.Button1Click(Sender: TObject); 
var 
    tTime : TDateTime; 
    iBcl : Integer; 
    LogSW: TStreamWriter; 
    FileName: TFileName; 
begin 
    FileName := 'c:\Test.txt'; 
    LogSW := InitLog(FileName); 
    try 
    lbl1.Caption := 'Go->' + FileName; 
    lbl1.Refresh; 
    tTime := Now; 

    For iBcl := 0 to 2000 do 
     LogSW.WriteLine(IntToStr(ibcl) + ' ' + 'lkjlkjlkjlkjlkjlkjlkj'); 

    lbl1.Caption := FormatDateTime('sss:zzz',Now - tTime); 
    finally 
    CloseLog(LogSW); 
    end; 
end; 

Answer 2

而是重新打開文件保存在磁盤上的關鍵數據，你可以使用FlushFileBuffers功能或通過調用CreateFile功能與FILE_FLAG_NO_BUFFERING和FILE_FLAG_WRITE_THROUGH標誌打開無緩衝I/O的文件（見Remarks部分在第一鏈接）。

Answer 3

看來你的問題是，你需要刷新每次寫操作之後的緩存，這樣，如果你的應用程序崩潰也不會丟失數據。

雖然我確定這裏的其他答案非常好，但您無需對代碼進行如此大的更改。所有你需要做的是在每次寫入之後調用Flush(FText)。

const 
    // 10 million tests 
    NumberOfTests = 1000000; 

    // Open and close with each write:  19.250 seconds 

    // Open once, and flush after each write: 5.686 seconds 

    // Open once, don't flush     0.439 seconds 

var 
    FText : Text; 
    TmpBuf: array[word] of byte; 

procedure initF(FileName : string); 
begin 
    {$I-} 
    if FileExists(FileName) then DeleteFile(FileName); 
    AssignFile(FText, FileName); 
    ReWrite(FText); 
    SetTextBuf(FText, TmpBuf); 
    {$I+} 
end; 

procedure CloseTheFile; 
begin 
    CloseFile(FText); 
end; 

Procedure AddToFile(Source: string); 
Begin 
    {$I-} 
    Writeln(FText, Source); 

    // flush the cache after each write so that data will be written 
    // even if program crashes. 
    flush (fText);    // <<<==== Flush the Cache after each write 

    {$I+} 
end; 

procedure TForm1.Button1Click(Sender: TObject); 
var tTime : TDateTime; 
    iBcl : Integer; 
    FileName : string; 
begin 
    FileName := 'c:\Test.txt'; 
    lbl1.Caption := 'Go->' + FileName; lbl1.Refresh; 
    initF(FileName); 

    // put file close in a try/finally block to ensure file is closed 
    // even if an exception is raised. 
    try 

    tTime := Now; 
    For iBcl := 0 to NumberOfTests-1 do 
     AddToFile(IntToStr(ibcl) + ' ' + 'lkjlkjlkjlkjlkjlkjlkj'); 
    lbl1.Caption := FormatDateTime('sss:zzz',Now-tTime); 

    finally 
    CloseTheFile; 
    end; 
end; 

Answer 4

由於某種原因，從一個文本文件，並寫入文本輸出文件的簡單閱讀中，我發現文本文件WriteLn仍然是最快的方法。

AssignFile(t,'c:\a\in.csv'); 
    Reset(t); 
    AssignFile(outt,'c:\a\out.csv'); 
    ReWrite(outt); 
    while not eof(t) do 
    begin 
    Readln(t,x); 
    WriteLn(outt, x); //27 sec, using LogSW.WriteLine(outx) takes 54 sec 

//半GB的文件用了27秒，上面的代碼，使用從TStreamWriter例如通過馬亭提供了54秒：○