在Perl中，如何將我從數據庫讀取的數組轉換爲散列？

Question

基本上，我查詢數據庫，我需要得到的數組轉換成哈希值。

我查詢數據庫如下

my $sth = $dbw->prepare($sql); 
while (@rows = $sth->fetchrow_array()) { 
... 
... 
} 

現在，我需要創建一個散列，使得行[0]是關鍵和行[1]，行[2]，行[3]是價值。對於每個記錄讀取，一個新的哈希鍵必須生成和相應的值設置

如果我的表看起來像

abc 2.3 2.4 2.5 
def 3.2 3.3 3.4 
ijk 4.5 4.6 4.7 

第一個記錄是閱讀和ABC的關鍵和數字的值。 ..所以上

Answer 1

my %hash; 

while (my @fields = $sth->fetchrow_array()) { 
    $hash{$fields[0]} = [ @fields[1..$#fields] ]; 
} 

Answer 2

my %mealsizes; 
my $sth = $dbw->prepare($sql); 
while (@columns = $sth->fetchrow_array()) { 
    my $dayname = shift @columns; 
    $mealsizes{$dayname} = [@columns]; 
} 

這裏的構造和使用的數組引用的圖示。

#!/usr/bin/perl 
# 
use strict; 
use warnings; 

my %h; 
while (<DATA>) { 
    my @columns = split; 
    my $k = shift @columns; 
    $h{$k} = [@columns]; 
} 

for my $k (sort keys %h) { 
    print "$k => ", join(', ', @{$h{$k}}), "\n"; 
} 

__DATA__ 
abc 2.3 2.4 2.5 
def 3.2 3.3 3.4 
ijk 4.5 4.6 4.7 

Answer 3

你也可以看看selectall_hashref。

$hash_ref = $dbh->selectall_hashref($statement, $key_field);