密碼查詢返回或僅保留使用可變長度關係標識符時的最終序列

Question

當使用變量長度標識符進行更深層次的操作時，是否有方法保留或僅返回最終的全部節點序列而不是所有子路徑每個最終全序列路徑上的操作。

MATCH路徑=（S：人） - [RELS：NEXT *] - >（E：人）................

例如：找到所有在給定列表中具有其名稱的節點序列，比如['graph'，'server'，'db']具有相同的'seqid'屬性。

即

（圖形） - >（服務器） - （分貝）與相同SEQID：1

（圖形） - >（分貝） - >（服務器）具有相同SEQID：1 //可以有另一個匹配
序列具有相同SEQID

（圖） - >（DB） - >（服務器）具有相同的SEQID：2

有沒有辦法只保留節點的最終序列說'（圖） - >（服務器） - >（db）'代替每個序列>（服務器）或（服務器） - - 樣（圖）大序列的子路徑>（DB）

請幫助我解決這個.........

（我在嵌入模式下使用neo4j 2.3.6社區版通過java api ..）

Answer 1

我們真的可以在這裏使用的是一個longestSequences（）函數，它可以完成您想要的操作，擴展模式，使a和b將始終與序列中的開始點和結束點匹配，以使模式不是任何其他匹配模式的子集。

我創建正是這種對Neo4j的功能要求：https://github.com/neo4j/neo4j/issues/7760

而且直到得到實施，我們將不得不湊合着用一些替代方法。我認爲我們要做的就是添加額外的匹配，將a和b限制爲完整序列的開始和結束節點。

這是我提出的查詢：

WITH ['graph', 'server' ,'db'] as names 
MATCH p=(a)-[rels:NEXT*]->(b) 
WHERE ALL(n in nodes(p) WHERE n.name in names) 
AND ALL(r in rels WHERE rels[0]['seqid'] = r.seqid) 
WITH names, p, a, rels, b 
// check if b is a subsequence node instead of an end node 
OPTIONAL MATCH (b)-[rel:NEXT]->(c) 
WHERE c.name in names 
AND rel.seqid = rels[0]['seqid'] 
// remove any existing matches where b is a subsequence node 
WITH names, p, a, rels, b, c 
WHERE c IS NULL 
WITH names, p, a, rels, b 
// check if a is a subsequence node instead of a start node 
OPTIONAL MATCH (d)-[rel:NEXT]->(a) 
WHERE d.name in names 
AND rel.seqid = rels[0]['seqid'] 
// remove any existing matches where a is a subsequence node 
WITH p, a, b, d 
WHERE d IS NULL 
RETURN p, a as startNode, b as endNode 

Answer 2

將帖子

此查詢可能會做你想要什麼：

MATCH (p1:Person)-[rel:NEXT]->(:Person) 
WHERE NOT (:Person)-[:NEXT {seqid: rel.seqid}]->(p1) 
WITH DISTINCT p1, rel.seqid AS seqid 
MATCH path = (p1)-[:NEXT* {seqid: seqid}]->(p2:Person) 
WHERE NOT (p2)-[:NEXT {seqid: seqid}]->(:Person) 
RETURN path; 

它首先識別所有Person節點（p1）至少一個傳出NEXT的關係，沒有傳入NEXT關係（與seqid相同），和他們明顯的傳出seqid值。然後，它從每個p1節點開始並且具有全部共享相同seqid的關係，找到所有「完整」路徑（即其開始和結束節點分別與期望的seqid沒有呼入或呼出關係的路徑）。最後，它返回每個完整的路徑。

如果你只是想獲得的所有Person節點的name財產的每個路徑，嘗試此查詢（用不同的RETURN條款）：

MATCH (p1:Person)-[rel:NEXT]->(:Person) 
WHERE NOT (:Person)-[:NEXT {seqid: rel.seqid}]->(p1) 
WITH DISTINCT p1, rel.seqid AS seqid 
MATCH path = (p1)-[:NEXT* {seqid: seqid}]->(p2:Person) 
WHERE NOT (p2)-[:NEXT {seqid: seqid}]->(:Person) 
RETURN EXTRACT(n IN NODES(path) | n.name); 

Answer 3

MATCH (S:Person)-[r:NEXT]->(:Person) 
    // Possible starting node 
    WHERE NOT ((:Person)-[:NEXT {seqid: r.seqid}]->(S)) 
WITH S, 
    // Collect all possible values of `seqid` 
    collect (distinct r.seqid) as seqids 
UNWIND seqids as seqid 
// Possible terminal node 
MATCH (:Person)-[r:NEXT {seqid: seqid}]->(E:Person) 
    WHERE NOT ((E)-[:NEXT {seqid: seqid}]->(:Person)) 
WITH S, 
    seqid, 
    collect(distinct E) as ES 
UNWIND ES as E 
    MATCH path = (S)-[rels:NEXT* {seqid: seqid}]->(E) 
RETURN S, 
     seqid, 
     path