拒絕了對FileSystemObject.CopyFile即使管理員

Question

所以我新到Windows部署，所以我在這裏可以做一些基本的錯誤。我試圖將腳本複製到Windows目錄中的文件夾使用MDT

基本上我想要的是試圖將腳本複製到％windir％\ temp \ deploymentscripts文件夾，但我甚至以管理員身份拒絕權限。我會通過我認爲我做的

First, elevate to admin 
Create %WinDir%\Temp\DeploymentScripts 
Copy DefaultShell.vbs to that directory (this is where I get permission denied 
Mount ntuser.dat to the registry 
Set DefaultShell.vbs to the Run Once for default users 
Unmount ntuser.dat 

運行下面是實際的代碼

Option Explicit 

If WScript.Arguments.length = 0 Then 
Dim wshShell : Set wshShell = CreateObject("Shell.Application") 
wshShell.ShellExecute "wscript.exe", """" & _ 
WScript.ScriptFullName & """" &_ 
" RunAsAdministrator", , "runas", 1 
Else 

Dim objFSO : Set objFSO = CreateObject("Scripting.FileSystemObject") 
Dim objShell : Set objShell = WScript.CreateObject("WScript.Shell") 
Dim TempDir 
Dim ParentDir 
Dim FullPath 
TempDir = objShell.ExpandEnvironmentStrings("%WinDir%\Temp\DeploymentScripts") 

If Not (objFSO.FolderExists(TempDir)) Then 
objFSO.CreateFolder (TempDir) 
End If 

ParentDir = objFSO.GetParentFolderName(Wscript.ScriptFullName) 
FullPath = ParentDir & "\DefaultShell.vbs" 

objFSO.CopyFile FullPath, TempDir, True 

objShell.run "reg load HKU\ZZZ C:\users\default\ntuser.dat" 
objShell.RegWrite "HKU\ZZZ\Software\Microsoft\Windows\RunOnce\DefaultShell", _ 
"WScript.exe" & " " & FullPath, "REG_SZ" 
objShell.run "reg unload HKU\ZZZ" 

End If 

Answer 1

有幾件事情：

1. 的tempDir變量未設置正確。添加一個尾部斜線，這應該工作。例如：

   TempDir = objShell.ExpandEnvironmentStrings("%WinDir%\Temp\DeploymentScripts\")

2. 一個。您指向錯誤的註冊表位置 - 您錯過了CurrentVersion。

   b。您參考的方式HKU在regwrite指令中可能會導致錯誤。如果它確實會導致錯誤，則僅針對該行，將其更改爲HKEY_USERS insdead HKU。

   如：

   objShell.RegWrite "HKEY_USERS\ZZZ\Software\Microsoft\Windows\Currentversion\RunOnce\defaultshell", _ "WScript.exe" & " " & FullPath, "REG_SZ"

3. 爲了確保你的腳本序列運行，我已經添加了幾個StdOut.ReadAll()指令。如果沒有，那麼即使您尚未完成加載配置單元，腳本仍將繼續處理。我想這只是簡單地告訴腳本等到reg命令完成後再繼續下一條指令。

下面是您的腳本的修訂版本，並且包含這些建議。

Option Explicit 

If WScript.Arguments.length = 0 Then 
    Dim wshShell : Set wshShell = CreateObject("Shell.Application") 
    wshShell.ShellExecute "wscript.exe", """" & _ 
    WScript.ScriptFullName & """" &_ 
    " RunAsAdministrator", , "runas", 1 

Else 

    Dim objFSO : Set objFSO = CreateObject("Scripting.FileSystemObject") 
    Dim objShell : Set objShell = WScript.CreateObject("WScript.Shell") 
    Dim TempDir, ParentDir, FullPath, Regload, Regresp 
    TempDir = objShell.ExpandEnvironmentStrings("%WinDir%\Temp\DeploymentScripts\") 

    If Not (objFSO.FolderExists(TempDir)) Then 
     objFSO.CreateFolder (TempDir) 
    End If 

    ParentDir = objFSO.GetParentFolderName(Wscript.ScriptFullName) 
    FullPath = ParentDir & "\DefaultShell.vbs" 
    objFSO.CopyFile FullPath, TempDir, True 

    Set regload = objShell.exec ("reg load HKU\ZZZ C:\users\default\ntuser.dat") 
    regresp = regload.StdOut.ReadAll() 

    objShell.RegWrite "HKEY_USERS\ZZZ\Software\Microsoft\Windows\Currentversion\RunOnce\DefaultShell", _ 
    "WScript.exe" & " " & FullPath, "REG_SZ" 

    Set regload = objShell.exec ("reg unload HKU\ZZZ") 
    regresp = regload.StdOut.ReadAll() 

End If