德爾福彈出框與圖像

Question

所以我是新來的德爾福，我有一個按鈕，當它被點擊它打開一個OpenPictureDialog。然後我想創建一個彈出框，並將該圖片加載到該框中。我不確定最好的方法是什麼？

我正在考慮在按鈕單擊事件上創建一個新窗體，然後將圖像放入該窗體中，但我無法弄清楚如何將TImage傳遞給窗體構造函數。

OpenPictureDialog1.Execute; 
img.Picture.LoadFromFile(OpenPictureDialog1.FileName); 
TForm2.Create(Application, img).Show; 

有沒有人有更好的想法，如何做到這一點或解決我想要做的事情？

謝謝。

Answer 1

你最好把TImage組件在您的輔助形式，並通過文件名，例如，創建一個表單這樣一個新的構造：

type 
    TForm2 = class(TForm) 
    Image1: TImage; 
    private 
    public 
    constructor CreateWithImage(AOwner: TComponent; AImgPath: string); 
    end; 

... 
implementation 
... 

constructor TForm2.CreateWithImage(AOwner: TComponent; AImgPath: string); 
begin 
    Create(AOwner); 
    Image1.Picture.LoadFromFile(AImgPath); 
end; 

然後，您可以創建和顯示你的表格是這樣：

procedure TForm1.Button1Click(Sender: TObject); 
var 
    Form2: TForm2; 
begin 
    if OpenPictureDialog1.Execute then 
    begin 
    Form2 := TForm2.CreateWithImage(Self, OpenPictureDialog1.FileName); 
    Form2.Show; 
    end; 
end; 

編輯

如果你想在運行時創建的圖像，你可以做這樣的：

type 
    TForm2 = class(TForm) 
    private 
    FImage: TImage; //this is now in the private section, 
        //and not the default (published) 
    public 
    constructor CreateWithImage(AOwner: TComponent; AImgPath: string); 
    end; 

... 
implementation 
... 

constructor TForm2.CreateWithImage(AOwner: TComponent; AImgPath: string); 
begin 
    Create(AOwner); 
    FImage := TImage.Create(Self); 
    FImage.Parent := Self; 
    FImage.Align := alClient; 
    FImage.Picture.LoadFromFile(AImgPath); 
end;