管理共享協議緩衝區庫，並使用Gradle編譯

我想有3個Java應用程序（後端，前端和Android應用程序）使用協議緩衝區（gRPC）進行通信。所以我希望這3個應用程序都能夠訪問共享的protobuf庫（Github），在這裏我管理.proto文件。我是使用Gradle和protobufs的新手，所以我不確定管理這個的正確方法是什麼，任何幫助或指導都不勝感激。我可以讓每個Gradle項目將我的github protobuf repo聲明爲依賴項，然後在構建項目時將其拉下並編譯它？因爲Android應用可能需要不同的「Java-lite」版本的protobufs，所以我會假設這種方式是實現它的一種好方法，而不是存儲已編譯的protobuf類。我正在使用google/protobuf-gradle-plugin來編譯.proto文件，並查看從本地文件進行編譯的文檔，或者拉入具有預編譯的.proto文件的項目，但沒有提供遠程.proto文件的文檔。我在正確的軌道上嗎？管理共享協議緩衝區庫，並使用Gradle編譯

來源

2017-08-07 bryant

你的遠程.proto文件/回購是什麼形式？如果它只是一個網址，那麼你可以使用下載任務：

buildscript { 
    repositories { 
     mavenCentral() 
    } 
    dependencies { 
     classpath 'com.google.protobuf:protobuf-gradle-plugin:0.8.0' 
    } 
} 

plugins { 
    id "de.undercouch.download" version "3.2.0" 
} 

group 'testtest' 
version '1.0-SNAPSHOT' 

apply plugin: 'java' 
apply plugin: 'com.google.protobuf' 


sourceCompatibility = 1.8 

repositories { 
    mavenCentral() 
} 

task downloadFile << { 
    download { 
     src 'https://raw.githubusercontent.com/grpc/grpc-java/master/compiler/src/test/proto/test.proto' 
     dest "$projectDir/src/main/proto/test.proto" 
     overwrite true 
    } 
} 

build.dependsOn downloadFile 

dependencies { 
    compile "io.grpc:grpc-protobuf-lite:1.5.0" 
    compile "io.grpc:grpc-stub:1.5.0" 
} 

protobuf { 
    protoc { 
     artifact = 'com.google.protobuf:protoc:3.3.0' 
    } 
    plugins { 
     javalite { 
      artifact = "com.google.protobuf:protoc-gen-javalite:3.0.0" 
     } 
     grpc { 
      artifact = "io.grpc:protoc-gen-grpc-java:1.5.0" 
     } 
    } 
    generateProtoTasks { 
     all().each { task -> 
      task.builtins { 
       remove java 
      } 
      task.plugins { 
       javalite {} 
       grpc { 
        option 'lite' 
       } 
      } 
     } 
    } 
}

來源

2017-09-06 00:28:51 user675693

管理共享協議緩衝區庫，並使用Gradle編譯

回答

相關問題