如何在填充某個其他屬性時使用XSLT替換XML屬性？

Question

我有兩個可能的XML文件：

<orders> 
    <order id="1"> 
     <code value="001-AAA"/> 
     <altCode value="002-BBB"/> 
    </order> 
</orders> 

和：

<orders> 
    <order id="2"> 
     <code value="001-AAA"/> 
     <altCode value=""/> 
    </order> 
</orders> 

我想<code>標籤的value屬性由<altCode>標籤的value屬性所取代，除非第二個值是空的。在那種情況下，我希望XML te保持不變。 <altCode>標籤不需要更改。

所以導致兩個XML文件應該是這樣的：

<orders> 
    <order id="1"> 
     <code value="002-BBB"/> 
     <altCode value="002-BBB"/> 
    </order> 
</orders> 

和：

<orders> 
    <order id="2"> 
     <code value="001-AAA"/> 
     <altCode value=""/> 
    </order> 
</orders> 

注： 實際的文件，我想轉換是一個複雜得多。所以我更喜歡複製模板並在使用when語句後更改屬性。

任何幫助，非常感謝。

Answer 1

我會建議你做：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<!-- identity transform --> 
<xsl:template match="@*|node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="code/@value[string(../../altCode/@value)]"> 
    <xsl:copy-of select="../../altCode/@value"/> 
</xsl:template> 

</xsl:stylesheet>