XSLT（XML to XML）輸出包含源不匹配的數據

Question

使用Visual Studio在開發過程中執行轉換時，生成的xml包含目標中的源xml文本，該文本包含在與我的模板條件不匹配的標記中

我期待我的選擇集團在第一個模板找到名爲組，是CrystalReport直接孩子的任何元素，並通過他們在應用模板調用。我知道我的第二個模板上的匹配過濾器只會在組的屬性爲Level = 1並將其寫出。我期望一切被忽略。

爲什麼「not this」出現在我的輸出中？

源

<?xml version="1.0" encoding="utf-8" ?> 
<!-- 
UPDATE: Note that adding the xmlns attribute causes all output 
to disappear unless you use Chris's second solution. 
--> 
<CrystalReport xmlns="urn:crystal-reports:schemas:report-detail" > 
    <Group Level="1"> 
    <GroupHeader> 
     <Section> 
     <Field FieldName="apple" /> 
     </Section> 
    </GroupHeader> 
    <Group Level="2"> 
     not this 
    </Group> 
    </Group> 
</CrystalReport> 

變換

<?xml version="1.0" encoding="utf-8"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

    <xsl:output method="xml" indent="yes"/> 
    <xsl:strip-space elements="*"/> 

    <xsl:template match="/CrystalReport"> 
    <root> 
     <xsl:apply-templates select="Group"/> 
    </root> 
    </xsl:template> 

    <xsl:template match="Group[@Level='1']/GroupHeader"> 
    <tag1><xsl:value-of select="Section/Field/@FieldName"/></tag1> 
    </xsl:template> 
</xsl:stylesheet> 

輸出

<?xml version="1.0" encoding="utf-8"?> 
<root> 
    <tag1>apple</tag1> 
     not this 
    </root> 

Answer 1

你正面臨在內置XML解析器的模板開始發揮作用的問題。您將模板應用於所有Group元素，但只能使用自己的模板捕捉其中一個模板。另一個由輸出所有節點值的默認模板處理。我建議你改變

<xsl:template match="/CrystalReport"> 

到

<xsl:template match="/"> 

這將覆蓋其產生額外的輸出根默認模板。您可以在http://www.w3.org/TR/xslt#built-in-rule

找到更多的內置模板規則然後覆蓋基本的文本（）模板，所以你最終XSLT看起來有點像這樣

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" indent="yes"/> 
<xsl:strip-space elements="*"/> 
<xsl:template match="/"> 
    <root> 
     <xsl:apply-templates select="CrystalReport/Group"/> 
    </root> 
</xsl:template> 
<xsl:template match="Group[@Level='1']/GroupHeader"> 
    <tag1> 
     <xsl:value-of select="Section/Field/@FieldName"/> 
    </tag1> 
</xsl:template> 
<xsl:template match="text()"/> 

UPDATE

或者更簡單，你可以匹配所需的元素，並使用類似這樣的東西

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" indent="yes"/> 
<xsl:strip-space elements="*"/> 
<xsl:template match="/CrystalReport"> 
    <root> 
     <xsl:apply-templates select="Group[@Level='1']/GroupHeader"/> 
    </root> 
</xsl:template> 
<xsl:template match="GroupHeader"> 
    <tag1> 
     <xsl:value-of select="Section/Field/@FieldName"/> 
    </tag1> 
</xsl:template> 

這將保留默認的文本（）模板，這可以非常方便。

Answer 2

嘗試

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:crystal="urn:crystal-reports:schemas:report-detail"> 
<xsl:output method="xml" indent="yes"/> 
<xsl:strip-space elements="*"/> 
<xsl:template match="/crystal:CrystalReport"> 
    <root> 
     <xsl:apply-templates select="crystal:Group[@Level='1']/crystal:GroupHeader"/> 
    </root> 
</xsl:template> 
<xsl:template match="crystal:GroupHeader"> 
    <tag1> 
     <xsl:value-of select="crystal:Section/crystal:Field/@FieldName"/> 
    </tag1> 
</xsl:template>