在emacs中向上和向下移動行/區域

Question

在emacs中向上或向下移動所選區域或行（如果沒有選擇），最簡單的方法是什麼？我正在尋找與eclipse中相同的功能（以M-up，M-down爲界）。

Answer 1

一條線可以使用transpose-lines綁定到C-x C-t。不過不知道地區。

我找到了this elisp片段，它可以做你想做的事情，除非你需要改變綁定。

(defun move-text-internal (arg) 
    (cond 
    ((and mark-active transient-mark-mode) 
    (if (> (point) (mark)) 
      (exchange-point-and-mark)) 
    (let ((column (current-column)) 
       (text (delete-and-extract-region (point) (mark)))) 
     (forward-line arg) 
     (move-to-column column t) 
     (set-mark (point)) 
     (insert text) 
     (exchange-point-and-mark) 
     (setq deactivate-mark nil))) 
    (t 
    (beginning-of-line) 
    (when (or (> arg 0) (not (bobp))) 
     (forward-line) 
     (when (or (< arg 0) (not (eobp))) 
      (transpose-lines arg)) 
     (forward-line -1))))) 

(defun move-text-down (arg) 
    "Move region (transient-mark-mode active) or current line 
    arg lines down." 
    (interactive "*p") 
    (move-text-internal arg)) 

(defun move-text-up (arg) 
    "Move region (transient-mark-mode active) or current line 
    arg lines up." 
    (interactive "*p") 
    (move-text-internal (- arg))) 

(global-set-key [\M-\S-up] 'move-text-up) 
(global-set-key [\M-\S-down] 'move-text-down) 

Answer 2

沒有內置的。您可以使用轉置線（C-x C-t），但不能反覆使用。看看http://www.schuerig.de/michael/blog/index.php/2009/01/16/line-movement-for-emacs/上的功能。

它也應該很容易適應地區。

Answer 3

transpose-paragraph功能可以幫助你。

您可能還想看看Emacs手冊中的轉置部分。 本質：

C-t 
Transpose two characters (transpose-chars). 
M-t 
Transpose two words (transpose-words). 
C-M-t 
Transpose two balanced expressions (transpose-sexps). 
C-x C-t 
Transpose two lines (transpose-lines). 

Answer 4

我已經寫了幾個互動功能動線向上/向下：

;; move line up 
(defun move-line-up() 
    (interactive) 
    (transpose-lines 1) 
    (previous-line 2)) 

(global-set-key [(control shift up)] 'move-line-up) 

;; move line down 
(defun move-line-down() 
    (interactive) 
    (next-line 1) 
    (transpose-lines 1) 
    (previous-line 1)) 

(global-set-key [(control shift down)] 'move-line-down) 

的綁定鍵是IntelliJ IDEA的風格，但你可以使用任何你想要的。我也許應該實現一些在各個地區運作的功能。

Answer 5

更新：安裝Marmalade的move-text包或MELPA獲取以下代碼。

這是我使用，這兩個地區和各條線的工作原理：

(defun move-text-internal (arg) 
    (cond 
    ((and mark-active transient-mark-mode) 
    (if (> (point) (mark)) 
     (exchange-point-and-mark)) 
    (let ((column (current-column)) 
      (text (delete-and-extract-region (point) (mark)))) 
     (forward-line arg) 
     (move-to-column column t) 
     (set-mark (point)) 
     (insert text) 
     (exchange-point-and-mark) 
     (setq deactivate-mark nil))) 
    (t 
    (let ((column (current-column))) 
     (beginning-of-line) 
     (when (or (> arg 0) (not (bobp))) 
     (forward-line) 
     (when (or (< arg 0) (not (eobp))) 
      (transpose-lines arg) 
      (when (and (eval-when-compile 
         '(and (>= emacs-major-version 24) 
          (>= emacs-minor-version 3))) 
        (< arg 0)) 
      (forward-line -1))) 
     (forward-line -1)) 
     (move-to-column column t))))) 

(defun move-text-down (arg) 
    "Move region (transient-mark-mode active) or current line 
    arg lines down." 
    (interactive "*p") 
    (move-text-internal arg)) 

(defun move-text-up (arg) 
    "Move region (transient-mark-mode active) or current line 
    arg lines up." 
    (interactive "*p") 
    (move-text-internal (- arg))) 


(global-set-key [M-S-up] 'move-text-up) 
(global-set-key [M-S-down] 'move-text-down) 

Answer 6

有一個在Emacs的維基只爲這一個條目：

http://www.emacswiki.org/emacs/MoveLine

對於運動區域：

http://www.emacswiki.org/emacs/MoveRegion

Answer 7

這裏是我的代碼片段來移動當前行或活動區域跨越的行。它尊重光標位置和突出顯示的區域。當該區域不以線邊界開始/結束時，它不會斷線。 （它是由偏食的啓發，我找到了日食的方式比「轉線」更方便。）

;; move the line(s) spanned by the active region up/down (line transposing) 
;; {{{ 
(defun move-lines (n) 
    (let ((beg) (end) (keep)) 
    (if mark-active 
     (save-excursion 
      (setq keep t) 
      (setq beg (region-beginning) 
       end (region-end)) 
      (goto-char beg) 
      (setq beg (line-beginning-position)) 
      (goto-char end) 
      (setq end (line-beginning-position 2))) 
     (setq beg (line-beginning-position) 
      end (line-beginning-position 2))) 
    (let ((offset (if (and (mark t) 
          (and (>= (mark t) beg) 
           (< (mark t) end))) 
         (- (point) (mark t)))) 
      (rewind (- end (point)))) 
     (goto-char (if (< n 0) beg end)) 
     (forward-line n) 
     (insert (delete-and-extract-region beg end)) 
     (backward-char rewind) 
     (if offset (set-mark (- (point) offset)))) 
    (if keep 
     (setq mark-active t 
       deactivate-mark nil)))) 

(defun move-lines-up (n) 
    "move the line(s) spanned by the active region up by N lines." 
    (interactive "*p") 
    (move-lines (- (or n 1)))) 

(defun move-lines-down (n) 
    "move the line(s) spanned by the active region down by N lines." 
    (interactive "*p") 
    (move-lines (or n 1))) 

Answer 8

你應該嘗試drag-stuff！

它的工作原理完全一樣日食Alt鍵 + 向上/下單線條，以及符合所選區域的線！

此外，它可以讓你與Alt鍵 + 左/右
這正是你要尋找移動的話！它甚至可以從ELPA repos！

其他解決方案從來沒有爲我工作。其中一些是越野車（在改變順序的同時換位線，wtf？），其中一些正在移動恰好選定的區域，而未選定部分的線位於其位置上。但是drag-stuff和eclipse完全一樣！

甚至更​​多！您可以嘗試選擇一個區域並使用Alt + Left/Right！這會將所選區域左移或右移一個字符。驚人！

要啓用全局簡單地運行這樣的：

(drag-stuff-global-mode) 

Answer 9

我用的是智能換檔組件（在Melpa）這一點。默認情況下，它重新綁定C-C <arrow>以移動一條線或區域。它按主模式特定的量水平移動（例如c-basic-offset或python-indent-offset）。也在地區工作。

;; binds C-C <arrows> 
(when (require 'smart-shift nil 'noerror) 
    (global-smart-shift-mode 1))