結合2個XML文件轉換成1使用XSL

Question

我無法找到一個合適的例子，以2個XML文件合併成1，如下面：

movies.xml

<movies> 
    <movie> 
     <name>ET</name> 
     <director>Steven Spielberg</director> 
     <date>15 January 2000</date> 
    </movie> 
    <movie> 
     <name>The Neverending Story</name> 
     <director>Steven Spielberg</director> 
     <date>4 November 2006</date> 
    </movie> 
</movies> 

directos.xml

<directors> 
    <director> 
     <name>Steven Spielberg</name> 
     <age>55</age> 
     <sex>male</sex> 
    </director> 
</directors> 

所需的輸出：

<directors> 
    <director> 
     <name>Steven Spielberg</name> 
     <age>55</age> 
     <sex>male</sex> 
     <movies> 
      <movie> 
       <name>ET</name> 
       <date>15 January 2000</date> 
      </movie> 
      <movie> 
       <name>The Neverending Story</name> 
       <date>4 November 2006</date> 
      <movie> 
     </movies> 
    </director> 
</directors> 

XSL：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method = "xml" indent = "yes" /> 

    <xsl:variable name="movieFile" select="document('movies.xml')" /> 

    <xsl:template match="@*|node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*|node()"/> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="$movieFile/movies/movie/director"> 
     <xsl:copy> 
      <xsl:apply-templates /> 
     </xsl:copy> 
    </xsl:template> 

</xsl:stylesheet> 

目前，正在打印每部電影組內的整個導演名單。

有人請給我一些指導嗎？

Answer 1

如果用這個代替你的第二個模板，喂「directors.xml」文件作爲輸入，它應該工作：

<xsl:template match="director"> 
    <xsl:variable name="director-name" select="name"/> 
    <xsl:copy> 
     <xsl:apply-templates select="@* | node()" /> 
    <xsl:apply-templates select="document('movies.xml')/movies/movie[director=$director-name]" /> 
    </xsl:copy> 
</xsl:template> 

您複製使用身份模板的每個節點除了director節點之上，在其中添加movie文件的匹配內容。

Answer 2

如果你的確可以使用XSLT 2.0，那麼這可能是很簡單的：

XSLT 2.0

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/> 

<xsl:variable name="movieFile" select="document('movies.xml')" /> 

<xsl:key name="movie-by-director" match="movie" use="director" /> 

<!-- identity transform --> 
<xsl:template match="@*|node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="director"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
     <movies> 
      <xsl:apply-templates select="key('movie-by-director', name, $movieFile)" /> 
     </movies> 
    </xsl:copy> 
</xsl:template> 

</xsl:stylesheet>