從一個數組到另一個數組傳遞隨機值沒有重複

Question

我有一個數組（說'origA'），其中包含20個值和另一個數組（說「itemA」只有1值，我需要推任何10隨機值「ORIGA」到「意達」的，但我不能把它已經被推到「意達」相同的值。

我們怎樣才能做到這一點？

Answer 1

// Define how many random numbers are required. 
const REQUIRED:int = 10; 

// Loop until either the original array runs out of numbers, 
// or the destination array reaches the required length. 
while(origA.length > 0 && itemA.length < REQUIRED) 
{ 
    // Decide on a random index and pull the value from there. 
    var i:int = Math.random() * origA.length; 
    var r:Number = origA[i]; 

    // Add the value to the destination array if it does not exist yet. 
    if(itemA.indexOf(r) == -1) 
    { 
     itemA.push(r); 
    } 

    // Remove the value we looked at this iteration. 
    origA.splice(i, 1); 
} 

Answer 2

您可以創建一個副本origA並從中刪除您添加到itemA的項目：

非優化的版本：

var origA:Array = [1, 2, 3, 4, 5, 6, 7]; 
var itemA:Array = [0]; 

var copyA:Array = origA.concat(); 
var N:int = 10; 
var n:int = Math.min(N, copyA.length); 

for (var i:int = 0; i < n; i++) { 
    // Get random value 
    var index:int = Math.floor(Math.random() * copyA.length); 
    var value:int = copyA[index]; 
    // Remove the selected value from copyA 
    copyA.splice(index, 1); 
    // Add the selected value to itemA 
    itemA.push(value); 
} 

trace(itemA); 
//0,1,7,2,6,4,3,5 

優化的版本（以length沒有電話，indexOf，splice或push環內）：

var origA:Array = [1, 2, 3, 4, 5, 6, 7]; 
var itemA:Array = [0]; 

var copyA:Array = origA.concat(); 
var copyALength:int = copyA.length; 
var itemALength:int = itemA.length; 
var N:int = 10; 
var n:int = Math.min(N, copyALength); 
for (var i:int = 0; i < n; i++) { 
    // Get random value 
    var index:int = Math.floor(Math.random() * copyALength); 
    var value:int = copyA[index]; 
    // Remove the selected value from copyA 
    copyA[index] = copyA[--copyALength]; 
    // Add the selected value to itemA 
    itemA[itemALength++] = value; 
} 

trace(itemA); 
//0,2,5,7,4,1,3,6 

---

EDIT1：如果你原來的數組只有幾個項目，在其他答案中使用我的第一個版本或任何其他解決方案。但是，如果它可能有數千個項目或更多，那麼我建議您使用我的優化版本。

---

編輯：2這裏是從含有1,000,000項的數組複製1,000隨機選擇的項目所花費的時間：

• 所有其他版本：2000ms
• 優化版本：12ms
• 無需克隆原始陣列的優化版本：1ms

Answer 3

這是一個真正的短。從原來的數組中刪除隨機項目，直到你達到MAX，然後CONCAT到目標磁盤陣列：

const MAX:int = 10; 
var orig:Array = [0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20]; 
var target:Array = []; 
var tmp:Array = []; 
var i : int = -1; 
var len : int = orig.length; 
while (++i < MAX && len > 0) { 
    var index:int = int(Math.random()*len); 
    tmp[i] = orig[index]; 
    orig[index] = orig[--len]; 
} 
target = target.concat(tmp); 

編輯刪除項目的

採納@ SCH的方式。這是他應該接受的答案。我只保留了這個while循環。