如何使用ID檢查記錄，然後如果記錄存在更新，如果不添加新記錄

Question

我已經創建了一個Excel用戶窗體來收集數據。我已將它連接到Access以轉儲數據。但是，我想每次用戶按下提交按鈕時更新Access。

基本上我需要Select語句來確定一個id的存在，那麼如果它不存在，我需要使用INSERT來添加新行。我對任何SQL都很新，所以任何幫助都會很棒。

這裏是我現在的代碼，我需要將它調整到ADO。

Sub Update() 
Dim cnn As ADODB.Connection 
Dim MyConn 
Dim rst As ADODB.Recordset 
Dim StrSql As String 

Set cnn = New ADODB.Connection 
MyConn = ThisWorkbook.Path & Application.PathSeparator & TARGET_DB 

With cnn 
    .Provider = "Microsoft.ACE.OLEDB.12.0" 
    .Open MyConn 

Set rst = New ADODB.Recordset 
rst.CursorLocation = adUseServer 
rst.Open Source:="Foam", ActiveConnection:=cnn, _ 
     CursorType:=adOpenDynamic, LockType:=adLockOptimistic, _ 
     Options:=adCmdTable 





StrSql = "SELECT * FROM Foam WHERE FoamID = " & txtMyID 
Set rst = CurrentDb.OpenRecordset(StrSql, dbOpenDynaset) 

If (rst.RecordCount = 0) Then 
    DoCmd.RunSQL "INSERT INTO Foam (ID, Part, Job, Emp, Weight, Oven) VALUES " & _ 
      "(" & txtID & ", '" & txtField1 & "', '" & txtField2 & "', '" & txtField3 & "', '" & txtField4 & "', '" & txtField5 & "');" 

End If 

' Close the connection 
    rst.Close 
    cnn.Close 
    Set rst = Nothing 
    Set cnn = Nothing 


End With 

End Sub 

Answer 1

我修改您的代碼示例就足以得到它的工作我的系統上，並在Excel 2007

測試這個版本當我使用的值對於與現有記錄的id匹配的lngId，該記錄在記錄集中打開，我可以更新其字段的值。

當lngId與現有記錄的id不匹配時，記錄集打開爲空[(.BOF And .EOF) = True]。在那種情況下，我添加一條新記錄並添加字段值。

Sub Update() 
    Const TARGET_DB As String = "database1.mdb" 
    Dim cnn As ADODB.Connection 
    Dim MyConn As String 
    Dim rst As ADODB.Recordset 
    Dim StrSql As String 
    Dim lngId As Long 

    Set cnn = New ADODB.Connection 
    MyConn = ThisWorkbook.Path & Application.PathSeparator & TARGET_DB 
    With cnn 
     .Provider = "Microsoft.ACE.OLEDB.12.0" 
     .Open MyConn 
    End With 

    lngId = 4 
    StrSql = "SELECT * FROM tblFoo WHERE id = " & lngId 
    Set rst = New ADODB.Recordset 
    With rst 
     .CursorLocation = adUseServer 
     .Open Source:=StrSql, ActiveConnection:=cnn, _ 
       CursorType:=adOpenDynamic, LockType:=adLockOptimistic, _ 
       Options:=adCmdText 
     If (.BOF And .EOF) Then 
      ' no match found; add new record 
      .AddNew 
      !ID = lngId 
      !some_text = "Hello World" 
     Else 
      ' matching record found; update it 
      !some_text = "Hello World" 
     End If 
     .Update 
     .Close 
    End With 

    Set rst = Nothing 
    cnn.Close 
    Set cnn = Nothing 
End Sub 

Answer 2

使用VBA，下面是如何查詢某個ID以檢查它是否存在的示例。如果它不然後通過INSERT聲明添加：

Dim rs As DAO.Recordset 
Dim StrSql As String 

StrSql = "SELECT * FROM MyTable WHERE ID = " & txtMyID 
Set rs = CurrentDb.OpenRecordset(StrSql, dbOpenDynaset) 

If (rs.RecordCount = 0) Then 
    DoCmd.RunSQL "INSERT INTO MyTable (ID, Field1, Field2) VALUES " & _ 
      "(" & txtID & ", '" & txtField1 & "', '" & txtField2 & "');" 
End If