德爾福XE2程序集

Question

我有以下功能在Delphi 2006中工作，但在Delphi XE2下，它在處理RET時給出訪問衝突錯誤或特權指令錯誤。

function Q_TrimChar(const S: string; Ch: Char): string; 
asm 
     PUSH ESI 
     MOV  ESI,ECX 
     TEST EAX,EAX 
     JE  @@qt 
     MOV  ECX,[EAX-4] 
     TEST ECX,ECX 
     JE  @@qt 
     PUSH EBX 
     PUSH EDI 
     MOV  EBX,EAX 
     MOV  EDI,EDX 
     XOR  EDX,EDX 
     MOV  EAX,ESI 
     CALL System.@LStrFromPCharLen 
     MOV  EDX,EDI 
     MOV  ECX,[EBX-4] 
@@lp1: CMP  DL,BYTE PTR [EBX] 
     JNE  @@ex1 
     INC  EBX 
     DEC  ECX 
     JNE  @@lp1 
     MOV  EDX,[ESI] 
     JMP  @@wq 
@@ex1: DEC  ECX 
@@lp2: CMP  DL,BYTE PTR [EBX+ECX] 
     JNE  @@ex2 
     DEC  ECX 
     JMP  @@lp2 
@@ex2: MOV  EDI,[ESI] 
     LEA  EDX,[EDI+ECX+1] 
@@lp3: MOV  AL,BYTE PTR [EBX+ECX] 
     MOV  BYTE PTR [EDI+ECX],AL 
     DEC  ECX 
     JNS  @@lp3 
@@wq: MOV  EAX,[ESI] 
     MOV  BYTE PTR [EDX],0 
     SUB  EDX,EAX 
     MOV  [EAX-4],EDX 
     POP  EDI 
     POP  EBX 
     POP  ESI 
     RET 
@@qt: MOV  EAX,ESI 
     CALL System.@LStrClr 
     POP  ESI 
end; 

我不知道程序集很好。問題是什麼？

Answer 1

我完全同意David的建議，只是在Pascal中編寫代碼，並提出了答案。除非分析表明這是一個真正的瓶頸，否則真的不需要ASM。這裏有兩個版本。第一個更容易閱讀，但第二個更高效：

function Q_TrimChar(const S: string; Ch: Char): string; 
begin 
    result := S; 
    while (result <> '') and (result[1] = Ch) do Delete(Result, 1, 1); 
    while (result <> '') and (result[Length(Result)] = Ch) do Delete(Result, Length(Result), 1); 
end; 

function Q_TrimChar(const S: string; Ch: Char): string; 
var 
    First, Last : integer; 
begin 
    First := 1; 
    Last := Length(S); 
    while (First < Last) and (S[First] = Ch) do inc(First); 
    while (Last >= First) and (S[Last] = Ch) do Dec(Last); 
    Result := copy(S, First, Last-First+1); 
end; 

Answer 2

Delphi 2006使用單字節ANSI字符，所以string是AnsiString,Char是AnsiChar。在Delphi 2009及更高版本中，使用了兩個字節的Unicode字符。這個函數不可能適用於兩個編譯器。

即使使用AnsiString和AnsiChar的標準破解也不起作用。最有可能的是，這個函數對RTL實現的假設在現代Delphi中不再有效。

我會在Pascal中重寫這個函數，讓編譯器完成這項工作。這不僅是解決當前問題的最快捷方式，它還將幫助您跨越64位編譯的障礙，並且您可以選擇解決這個問題。