在批處理程序中添加用戶界面

我有這段代碼。在批處理程序中添加用戶界面

@ECHO OFF 
    :Values 
    SET strSSID= 
    SET strPWD= 
    ECHO Please enter the ssid: 
    SET /p strSSID=SSID: 
    ECHO. 
    ECHO Please enter the password: 
    SET /p strPWD=Password: 

    IF ".%strSSID%"=="." GOTO :TryAgain 
    IF ".%strPWD%"=="." GOTO :TryAgain 

    CALL :HostedNW "%strSSID%" "%strPWD%" 
    pause 
    GOTO :EOF 
    :HostedNW 
    ECHO 
    C:\Windows\System32\netsh.exe wlan set hostednetwor mode=allow ssid="%~1" key="%~2" keyUsage=persistent 
    SET strSSID= 
    SET strPWD= 
    GOTO :EOF 
    :TryAgain 
    CLS 
    ECHO. 
    ECHO One or more inputs weren't correct. 
    ECHO Please try again. 
    ECHO. 
    GOTO :Values

在我從用戶採取了適當的輸入作爲SSID和密碼，現在我有第二代碼爲：

C:\Windows\System32\netsh.exe wlan start hostednetwork

此代碼將接通無線網絡，和另一個代碼是：

C:\Windows\System32\netsh.exe wlan stop hostednetwork

此代碼將關閉WiFi。現在我想要所有這些代碼在一個編碼格式，並希望顯示一個適當的用戶界面，其中：第一個可點擊的按鈕將顯示「配置WiFi」第二個可點擊的按鈕將顯示「打開」第三個可點擊的按鈕將顯示「轉關「第四個可點擊的按鈕將退出用戶界面。

並且相應的按鈕將以與上述相同的方式運行爲其設計的相應代碼。如果可能，建議我如何改進此文件的用戶界面。請幫我解決這個問題。。。

來源

2014-11-09 SwaPnil Magar

批處理是基於文本的，這意味着它不能進行任何點擊操作。 – SomethingDark 2014-11-09 07:17:33

好吧，我明白了。但是，是否可以製作一個文件，其中顯示4個選項並要求特定 – 2014-11-09 07:26:25

當然，您可以執行基於文本的菜單。如果你正在運行比XP更早的系統，你可以使用'choice'命令，否則使用'set/p'和一些if語句。 – SomethingDark 2014-11-09 07:28:26

希望這是沿着你所尋找的東西。

@echo off 

:mainmenu 
cls 
echo ********************* 
echo *  WiFi Menu  * 
echo ********************* 
echo * 1. Configure WiFi * 
echo * 2. Enable WiFi * 
echo * 3. Disable WiFi * 
echo * 4. Quit   * 
echo ********************* 
choice /C:1234 >nul 

if %errorlevel% equ 1 goto config 
if %errorlevel% equ 2 goto enable 
if %errorlevel% equ 3 goto disable 
if %errorlevel% equ 4 goto quit 

:quit 
exit /b 

:config 
set "strSSID=" 
set "strPWD=" 

:: Enter the SSID and password 
set /p "strSSID=Please enter the SSID: " 
set /p "strpwd=Please enter the password: " 

:: Ensure that the user input is not empty 
if "%strSSID%"=="" goto tryagain 
if "%strPWD%"=="" goto tryagain 

:: Affiliate the SSID with the password 
netsh wlan set hostednetwork mode=allow ssid="%strSSID%" key="%strPWD%" keyUsage=persistent 
echo Wifi configured 
pause 
goto mainmenu 

:: Inform the user that required information was not supplied 
:tryagain 
cls 
echo. 
echo Please input both an SSID and password. 
echo. 
goto config 

:: Activate the WiFi 
:enable 
netsh wlan start hostednetwork 
echo WiFi enabled 
pause 
goto mainmenu 

:: Disable the WiFi 
:disable 
netsh wlan stop hostednetwork 
echo WiFi disabled 
pause 
goto mainmenu

來源

2014-11-09 08:27:05 SomethingDark

謝謝先生您的寶貴幫助。 – 2014-11-09 09:47:52

在批處理程序中添加用戶界面

回答

相關問題