我如何區分TDateTime屬性和RTTI的Double屬性？

Question

在Delphi 2010中使用RTTI系統，有沒有什麼辦法可以找出屬性是否是TDateTime？目前，當我將其作爲變量回撥並且如果檢查屬性類型時，它將其視爲雙倍數。這是由於它只能看到基本類型嗎？ （TDateTime類型=雙）

Answer 1

嘗試檢查的TRttiProperty.PropertyType

的Name財產我沒有德爾福2010年做的，但這部作品在XE。

{$APPTYPE CONSOLE} 

uses 
    SysUtils, 
    Classes, 
    Rtti; 

type 
    TMyClass =class 
    private 
    FDate: TDateTime; 
    FProp: Integer; 
    FDate2: TDateTime; 
    FDate1: TDateTime; 
    public 
    property Date1 : TDateTime read FDate1 Write FDate1; 
    property Prop : Integer read FProp Write FProp; 
    property Date2 : TDateTime read FDate2 Write FDate2; 
    end; 

var 
ctx : TRttiContext; 
t : TRttiType; 
p : TRttiProperty; 
begin 
ctx := TRttiContext.Create; 
try 
    t := ctx.GetType(TMyClass.ClassInfo); 
    for p in t.GetProperties do 
    if CompareText('TDateTime',p.PropertyType.Name)=0 then 
    Writeln(Format('the property %s is %s',[p.Name,p.PropertyType.Name])); 
finally 
    ctx.Free; 
end; 
    Readln; 
end. 

這個代碼在這裏返回

the property Date1 is TDateTime 
the property Date2 is TDateTime 

Answer 2

關鍵點，同時定義類型爲型指令。這兩個定義是不同的：

Type 
    TDateTime = Double; // here p.PropertyType.Name returns Double 

but 

Type 
    TDateTime = type Double; // here p.PropertyType.Name returns TDateTime 

or 

Type 
    u8 = type Byte; // here p.PropertyType.Name returns u8 

but 

Type 
    u8 = Byte; // here p.PropertyType.Name returns Byte !