XSLT 1.0計數以下姐弟

Question

我有這樣

<root> 
      <story> 
      <strongp> 
       <color>Attention</color> 
       Text of the single strongp color. 
      </strongp> 
      <p>Text</p> 
      <strongp> 
       <color>Attention</color> 
       Text of strongp color. 
      </strongp> 
      <strongp> 
       Text of interest1 
       <a id="1234-3457">here</a>. 
      </strongp> 
      <p>sometext</p> 
      <p>sometext</p> 
      <el>sometext</el> 
      <h5>Header H5</h5> 
      <strongp> 
       <color>Attention</color> 
       Text of strongp color. 
      </strongp> 
      <strongp> 
       Text of interest 
       <a id="8909-3490">here</a> 
      </strongp> 
      <strongp> 
       Text of interest 
       <a id="8909-0081">here</a> 
      </strongp> 
      <strongp> 
       Text of interest 
       <a id="8967-001">here</a> 
      </strongp> 
      <p>Text</p> 

      <inline /> 
     </story> 
    </root> 

一個簡單的XML需要轉換成strongp[color]和remarkheader以下的兄弟姐妹到remarktext和包裝這一切<remark>。

爲單<strongp>與顏色所需的輸出：

<remark> 
    <remarkheader>Attention</remarkheader> 
    <remarktext>Text of the single strongp color.</remarktext> 
</remark> 

和輸出用於strongp with color隨後用1個同級strongp是：

<remark> 
    <remarkheader>Attention</remarkheader> 
    <remarktext>Text of strongp color.<br/>Text of interest1 
       <a id="1234-3457">here</a>.</remarktext> 
</remark> 

最後輸出strongp color接着超過1 strongp

<remark> 
    <remarkheader>Attention</remarkheader> 
    <remarktext> 
     Text of strongp color. 
     <br/> 
     Text of interest1 
     <a id="1234-3457">here</a>. 
    <br/> 
     Text of interest 
     <a id="8909-3490">here</a>. 
    <br/> 
     Text of interest 
     <a id="8909-0081">here</a>. 
    <br/> 
     Text of interest 
     <a id="8967-001">here</a>. 
    </remarktext> 
</remark> 

那麼，應用此模板

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes" /> 
    <xsl:template match="node()|@*" name="identity" > 
     <xsl:copy> 
      <xsl:apply-templates select="node()|@*"/> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="strongp[color]"> 
     <remark> 
      <remarkheader> 
       <xsl:value-of select="./color"/> 
      </remarkheader> 
      <remarktext> 
       <xsl:value-of select="substring-after(., color)"/> 
       <br/> 
       <xsl:for-each select="following-sibling::strongp[count(preceding-sibling::strongp[color][1] | current())=1]"> 
        <xsl:apply-templates select="./node()" /> 
        <xsl:choose> 
         <xsl:when test="position() !=last()"> 
          <br/> 
         </xsl:when> 
        </xsl:choose> 
       </xsl:for-each> 
      </remarktext> 
     </remark> 
    </xsl:template> 

</xsl:stylesheet> 

但它似乎並沒有很好地工作。它添加了來自第一個後續兄弟strongp[color]的文本。我真的不明白它是如何影響下面的兄弟姐妹。

你可以看一下在這裏 http://www.utilities-online.info/xsltransformation/?save=c1b3e857-b6d7-4562-a440-9d3e357cb12d-xsltransformation

Answer 1

這裏是我的嘗試，處理following-sibling::strongp遞歸：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes" /> 
<xsl:strip-space elements="*"/> 

<xsl:template match="node()|@*"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="strongp[color]"> 
    <remark> 
     <remarkheader> 
      <xsl:value-of select="color"/> 
     </remarkheader> 
     <remarktext> 
      <xsl:apply-templates select="text()"/> 
      <xsl:apply-templates select="following-sibling::*[1][self::strongp]" mode="following"/> 
     </remarktext> 
    </remark> 
</xsl:template> 

<xsl:template match="strongp" mode="following"> 
    <br/> 
    <xsl:apply-templates select="node()"/> 
    <xsl:apply-templates select="following-sibling::*[1][self::strongp]" mode="following"/> 
</xsl:template> 

<xsl:template match="strongp"/> 

</xsl:stylesheet>