在PowerPoint演示文稿中旋轉3D圖表

Question

我在Excel中創建了一個可以旋轉3D圖表的宏。我將圖表複製到PowerPoint中，將代碼設置爲在幻燈片顯示時在PowerPoint中運行。代碼運行，但我無法實際改變屏幕上顯示的內容。幻燈片處於編輯模式時，圖形將旋轉。任何想法如何讓代碼不只是運行（我可以看到調試數字顯示），但更新屏幕時，在演示模式？我的代碼是：

Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long) 

Public Sub SpinTheChart() 

    RotateX = ActivePresentation.Slides(2).Shapes(2).Chart.ChartArea.Format _ 
        .ThreeD.RotationX 

    Do While ActivePresentation.SlideShowWindow.View.CurrentShowPosition = 2 
     RotateX = RotateX + 7 
     If RotateX > 360 Then RotateX = RotateX - 360 
     ActivePresentation.Slides(2).Shapes(2).Chart.ChartArea.Format _ 
        .ThreeD.RotationX = RotateX 
     DoEvents 
     Sleep 125 
     Debug.Print RotateX 
    Loop 

End Sub 

Sub OnSlideShowPageChange() 
    Dim i As Integer 
    i = ActivePresentation.SlideShowWindow.View.CurrentShowPosition 
    If i = 2 Then SpinTheChart 
End Sub 

更新： 我還在爲此而戰。這似乎有些recomendations說來更新當前顯示的圖表，你需要使用時，下面的DoEvents：

SlideShowWindows(1).View.GotoSlide SlideSowWindows(1).View.CurrentShowPosition 

但這不起作用。它退出正在運行的任何代碼。所以第一個函數中的Do/Loop被退出，並且不會繼續執行第二次迭代。

Answer 1

看起來圖表上的更改不會觸發SlideShowView刷新。但在形狀上的文字的變化將做到這一點。因此，以下代碼將旋轉圖表：

Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long) 

Public Sub SpinTheChart() 

Set oSlide = ActivePresentation.Slides("Slide1") 
Set oChart = oSlide.Shapes("Diagramm 4").Chart 
oChart.ChartArea.Format.ThreeD.RotationX = 20 

snRotationX = oChart.ChartArea.Format.ThreeD.RotationX 

Do While ActivePresentation.SlideShowWindow.View.Slide.Name = "Slide1" 

    snRotationX = snRotationX + 7 
    If snRotationX > 360 Then snRotationX = snRotationX - 360 
    oChart.ChartArea.Format.ThreeD.RotationX = snRotationX 

    'oSlide.Shapes("Rechteck 7").TextFrame.TextRange.Text = snRotationX 
    oSlide.Shapes.Title.TextFrame.TextRange.Text = oSlide.Shapes.Title.TextFrame.TextRange.Text 

    DoEvents 
    Sleep 125 

Loop 
End Sub 

Sub OnSlideShowPageChange(ByVal SSW As SlideShowWindow) 
If SSW.View.Slide.Name = "Slide1" _ 
    Then SpinTheChart 
End Sub 

您在Powerpoint演示期間熟悉宏的其他問題？他們在這樣的環境中非常脆弱，他們的影響必須仔細測試。

而OnSlideShowPageChange僅在VBA之前被激活時才起作用。最簡單的方法是在開始演示之前打開和關閉VBA編輯器。

問候

阿克塞爾

Answer 2

如果圖表旋轉在編輯模式下，你爲什麼不記錄它作爲一個.gif的包括在演示文稿中？

添加GIF動畫到PowerPoint：https://support.office.com/en-us/article/Add-an-animated-GIF-to-a-slide-3a04f755-25a9-42c4-8cc1-1da4148aef01

錄製屏幕：http://www.screentogif.com