在Perl中進行數組排序

Question

我是Perl新手，並且遇到了一個（可能很簡單）的數組排序問題。

我已經繼承了一些Perl代碼，它將文本文件中的行讀入三個一維數組（x，y，z）。我希望能夠使用其中一個維度作爲關鍵字對這些數組進行排序，並將其他兩個維度重新排序以匹配。

例如，如果我的輸入是：

• @x =（1，3,2）
• @y =（11,13,12）
• @z =（21， 23,22）

和我排序的x，我想得到的結果是：

• @x =（1，2，3）
• @y =（11,12,13）
• @z =（21,22,23）

我可以在三個1 d陣列合併成2-d陣列如果使壽命更輕鬆。

Answer 1

use strict; 
use warnings; 
use Data::Dumper; 

use List::Util qw(reduce); 

my @x = (1, 3, 2); 
my @y = (11, 13, 12); 
my @z = (21, 23, 22); 

my @combined = map { [ $x[$_], $y[$_], $z[$_] ] } 0 .. $#x; 
my @sorted = sort { $a->[0] <=> $b->[0] } @combined; 
my $split_ref = reduce { push @{$a->[$_]}, $b->[$_] for 0 .. $#$a; $a;} [[], [], []], @sorted; 

print Dumper \@combined; 
print Dumper \@sorted; 
print Dumper $split_ref; 

這將基本上給你：

[ 
     [ 
     1, 
     2, 
     3 
     ], 
     [ 
     11, 
     12, 
     13 
     ], 
     [ 
     21, 
     22, 
     23 
     ] 
    ]; 

Answer 2

做

@a = sort { $a <=> $b } @a; 

另見sort on perldoc。

Answer 3

合併確實可能會使生活更輕鬆。

@sorted = sort { $a->[0] <=> $b->[0] } 
    ([$x[0], $y[0], $z[0]], [$x[1], $y[1], $z[1]], [$x[2], $y[2], $z[2]]); 

可能會這樣做。你當然不想用手寫出所有的東西！

Answer 4

如果@x與@y和@z的大小相同，則不需要排序 - 您可以改爲使用數組切片！

use strict; 
use warnings; 
use 5.010; 

my @x = (1, 3, 2); 
my @y = (11,13,12); 
my @z = (21,23,22); 

say join ', ', @y; 
@y = @y[ map { $_ - 1 } @x ]; #We use map create a lists of the values of elements in @x, minus 1. 
say join ', ', @y; 

當然，如果你只是想通過數字順序進行排序，然後使用@x是多餘的：

@y = sort { $a <=> $b } @y; 

最後，如果要排序數組的任意號碼，你可以創建數組的數組，或通過引用列表到了，阿拉

my @indexes = map { $_ - 1 } @x; 

for my $array_ref (\@x, \@y, \@z) { 
    @$array_ref = @{$array_ref}[@indexes]; 
} 

Answer 5

有一試：

#!/usr/bin/perl 
use 5.10.1; 
use strict; 
use warnings; 
use Data::Dumper; 

my @x = (1, 3, 2); 
my @y = (11,13,12); 
my @z = (21,23,22); 

my (%y, %z); 

@y{@x} = @y; 
@z{@x} = @z; 

my @xs = sort @x; 
my @ys = @y{@xs}; 
my @zs = @z{@xs}; 
say Dumper \@xs,\@ys,\@zs; 

輸出：

$VAR1 = [ 
      1, 
      2, 
      3 
     ]; 
$VAR2 = [ 
      11, 
      12, 
      13 
     ]; 
$VAR3 = [ 
      21, 
      22, 
      23 
     ]; 

Answer 6

合併所有的數組在一起是沒有必要的。使用sort以獲取元素的正確索引排序在@x：

@sort_by_x = sort { $x[$a] <=> $x[$b] } 0 .. $#x; # ==> (0, 2, 1) 

那麼該索引的順序適用於任何其他數組：

@x = @x[@sort_by_x]; 
@y = @y[@sort_by_x]; 
@z = @z[@sort_by_x];