轉換日期時間格式之間使用Perl

Question

我們目前正在使用第三方API，它提供了以下格式的日期時間：

Sat Mar 06 09:00:00 ICST 2010 
Fri Feb 19 19:30:00 JDT 2010 
Fri Feb 19 19:30:00 PST 2010 

但是，我們要在MySQL這些datetime對象存儲在一個標準的日期時間字段，需要的格式如下：

YYYY-MM-DD HH:MM:SS 

現在，讓我們用下面的代碼被報告某些時區，如KDT，JDT和ICST錯誤：

use Date::Manip; 
use DateTime; 
use DateTime::Format::DateManip; 

my $date = ParseDate($time); 
$date = DateTime::Format::DateManip->parse_datetime($date); 
eval{ $time = $date->strftime("%Y-%m-%d %H:%M:%S"); }; 

你能推薦一個更好的實現上面的Perl代碼來將API中的日期時間對象轉換爲正確的格式和時間在我們的服務器上插入MySQL日期時間字段嗎？

在此先感謝您的幫助&意見！

Answer 1

商店的時間內在GMT。在GMT進行所有操作。然後在最後一刻，就像您即將向用戶顯示結果一樣，，然後將轉換爲用戶的本地時間。

我推薦使用Date::Parse，但是你必須增加它的時區偏移量，因爲它目前沒有印度支那夏令時和日本夏令時。

#! /usr/bin/perl 

use warnings; 
use strict; 

use Date::Format; 
use Date::Parse; 

# add timezone offsets 
$Time::Zone::Zone{icst} = +7*3600; 
$Time::Zone::Zone{jdt} = +9*3600; 

while (<DATA>) { 
    chomp; 
    warn("$0: failed conversion for $_\n"), next 
    unless defined(my $time_t = str2time $_); 

    my @t = gmtime($time_t); 
    print $_, " => ", strftime("%Y-%m-%d %H:%M:%S", @t), "\n"; 
} 

__DATA__ 
Sat Mar 06 09:00:00 ICST 2010 
Fri Feb 19 19:30:00 JDT 2010 
Fri Feb 19 19:30:00 PST 2010 

輸出：

Sat Mar 06 09:00:00 ICST 2010 => 2010-03-06 02:00:00 
Fri Feb 19 19:30:00 JDT 2010 => 2010-02-19 10:30:00 
Fri Feb 19 19:30:00 PST 2010 => 2010-02-20 03:30:00

支持你想查詢，存儲在格林尼治標準時間加上偏移（即，從格林尼治標準時間從API的本地時間）的時間。請注意，下面的代碼假設，如果str2time可以解析給定的時間，strptime也可以。更改環路

my @dates; 
while (<DATA>) { 
    chomp; 
    warn("$0: failed conversion for $_\n"), next 
    unless defined(my $time_t = str2time $_); 

    my $zone = (strptime $_)[-1]; 
    my @t = gmtime($time_t); 
    push @dates => [ strftime("%Y-%m-%d %H:%M:%S", @t) 
       , sprintf("%+03d:%02d", 
          int($zone/3600), 
          int($zone % 3600)/60) 
       , $_ 
       ]; 
} 

隨着收集的時間，呈現爲SQL：

print "DROP TABLE IF EXISTS dates;\n", 
     "CREATE TABLE dates (date DATETIME, offset CHAR(6));\n", 
     "INSERT INTO dates (date,offset) VALUES\n", 
     join(",\n\n" => 
      map(" -- $_->[2]\n" . 
       " ('$_->[0]','$_->[1]')", @dates)), 
     ";\n", 
     "SELECT CONVERT_TZ(date,'+00:00',offset) FROM dates;\n" 

輸出是

DROP TABLE IF EXISTS dates; 
CREATE TABLE dates (date DATETIME, offset CHAR(6)); 
INSERT INTO dates (date,offset) VALUES 
    -- Sat Mar 06 09:00:00 ICST 2010 
    ('2010-03-06 02:00:00','+07:00'), 

    -- Fri Feb 19 19:30:00 JDT 2010 
    ('2010-02-19 10:30:00','+09:00'), 

    -- Fri Feb 19 19:30:00 PST 2010 
    ('2010-02-20 03:30:00','-08:00'); 
SELECT CONVERT_TZ(date,'+00:00',offset) FROM dates; 

而且我們可以把它管mysql：

$ ./prog.pl | mysql -u username -D dbname 
CONVERT_TZ(date,'+00:00',offset) 
2010-03-06 09:00:00 
2010-02-19 19:30:00 
2010-02-19 19:30:00

Answer 2

嘗試使用DateTime模塊。

Answer 3

存儲日期時，應始終使用UTC存儲它們。這樣，您可以從數據庫中獲取它們，並根據需要將它們轉換爲適當的時區，以便向用戶顯示。

爲了在Perl中正確處理日期時間，我衷心推薦DateTime套件，該套件具有用於各種輸入和輸出格式的解析器和格式器。

我不知道，如果在你的OP所列日期的標準格式，但如果沒有，那將是很容易構建從他們DateTime格式：

my $str = 'Sat Mar 06 09:00:00 ICST 2010'; 
my ($month, $day, $hour, $min, $sec, $tz, $year) = ($str =~ m{\w{3}\s(\w{3})\s(\d{2})\s(\d{2}):(\d{2}):(\d{2})\s(\w+)\s(\d{4})}); 

my $dt = DateTime->new(year => $year, month => $month, day => $day, 
         hour => $hour, minute => $min, second => $sec, 
         time_zone => $tz); 

然後，您可以使用DateTime::Format::MySQL將日期轉換爲與MySQL兼容的日期時間。

Answer 4

您可能必須明確告訴DateTime構造函數您正在處理哪些時區，因爲三個和四個字母的代碼不是唯一的，也不是標準化的。

我建議從DateTime::TimeZone開始，如果在列表中找不到要查找的內容，則可能會爲時區創建新類型。你也可以找到一個符合你的語法的DateTime格式器（它們的數量很多），但是否則簡單地使用正則表達式來提取日期和時間字段並將它傳遞給DateTime構造函數並不困難。

一旦你得到了你的字符串解析與正確設置的時間datetime對象，這是一點問題都沒有將它們轉換回來了到MySQL時間戳：只需使用DateTime::Format::MySQL：

my $string = DateTime::Format::MySQL->format_datetime($dt);