批處理腳本遞歸循環子目錄，並找到2個文件夾中的丟失文件

Question

我想遞歸地比較2個文件夾，並在其中找到丟失的文件。我正在使用for循環來比較2個文件夾，但無法搜索子文件夾。有人可以幫忙嗎？

這裏是我試過的代碼，

@echo off 
if "%2" == "" GOTO Usage 

cd /D %1 
if errorlevel 1 goto usage 

for %%x in (*.*) do if NOT exist %2\%%x echo missing %2\%%x 
cd /D %2 
for %%x in (*.*) do if NOT exist %1\%%x echo missing %1\%%x 

goto end 

:usage 
echo Usage %0 dir1 dir2 
echo where dir1 and dir2 are full paths 
:end 

Answer 1

嘗試這一點，解釋見代碼中的註釋：

@ECHO OFF &SETLOCAL 
SET "folder1=this" 
SET "folder2=that" 

REM delete variables 
FOR /f "delims==" %%a IN ('set "$"') DO SET "%%a=" 

REM scanning folder1 
FOR /r "%folder1%" %%a IN (*) DO SET "$%%~nxa=%%~a" 

REM compare with folder2 
FOR /r "%folder2%" %%a IN (*) DO (
    IF NOT DEFINED $%%~nxa ECHO missing IN %folder1%: %%a 
) 

REM delete variables 
FOR /f "delims==" %%a IN ('set "$"') DO SET "%%a=" 

REM scanning folder2 
FOR /r "%folder2%" %%a IN (*) DO SET "$%%~nxa=%%~a" 

REM compare with folder1 
FOR /r "%folder1%" %%a IN (*) DO (
    IF NOT DEFINED $%%~nxa ECHO missing IN %folder2%: %%a 
) 

ECHO Done. 

Answer 2

@ECHO OFF 
SETLOCAL 
XCOPY /l /y /d "%~1\*" "%~2\*"|FIND "\" 
XCOPY /l /y /d "%~2\*" "%~1\*"|FIND "\" 
GOTO :EOF 

不嚴格，其中列出了在文件一個目錄但不在另一個目錄中;列出那些以及那些存在於兩者中但具有不同時間戳的那些。

將/s添加到XCOPY選項也可以掃描子目錄。