XSLT - 在REST響應結果轉換XML

目前我正在嘗試使用XSLT一些XML僞代碼轉換爲休息響應結果XSLT - 在REST響應結果轉換XML

例如，下面的XML：

<?xml version="1.0" encoding="UTF-8"?> 
<root xmlns:functions="http://foo.com/api/rest"> 
    <item bar="foo">some item</item> 
    <functions:fetch a="3" b="foo" /> 
</root>

而且如果http://foo.com/services/rest/fetch/a/3/b/foo結果是：

<?xml version="1.0" encoding="UTF-8"?> 
<rsp stat="ok"> 
    <book> 
    <title>Ethics</title> 
    </book> 
    <book> 
    <title>Beyond Good and Evil</title> 
    </book> 
</rsp>

的XSLT解析我試圖得到的結果是：

<?xml version="1.0" encoding="UTF-8"?> 
<root xmlns:functions="http://foo.com/api/rest"> 
    <item bar="foo">some item</item> 
    <book> 
    <title>Ethics</title> 
    </book> 
    <book> 
    <title>Beyond Good and Evil</title> 
    </book> 
</root>

我知道我可以使用<xsl:value-of select="document('http://foo.com/services/rest/fetch/a/3/b/foo')"/>來提出請求，但我堅持如何在同一個XSLT中生成和處理它。

任何幫助將不勝感激，提前致謝！

來源

2011-12-02 Eric

這裏是一個可能的純XSLT 1.0解決方案：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:functions="http://foo.com/api/rest" 
exclude-result-prefixes="functions"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:variable name="vDynPart"> 
    <xsl:for-each select="/*/functions:*/@*"> 
    <xsl:value-of select="concat('/', name(), '/', .)"/> 
    </xsl:for-each> 
</xsl:variable> 

<xsl:variable name="vRes" select= 
    "document(concat('http://foo.com/services/rest/fetch', 
        $vDynPart) 
      )"/> 

<xsl:template match="node()|@*"> 
    <xsl:copy> 
    <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="/"> 
    <xsl:copy> 
    <xsl:copy-of select="@*"/> 
    <xsl:apply-templates/> 

    <xsl:apply-templates select="$vRes/*/node()"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="functions:*"/> 
</xsl:stylesheet>

來源

2011-12-02 05:48:02

感謝來自Dimitre答案，我找到了解決辦法！

（我提出一個新的回覆，因爲我調整Dimitre解決一點與任何函數名，並在同一個XML多種功能工作）

這裏XSLT：

<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:functions="http://foo.com/api/rest" 
    exclude-result-prefixes="functions"> 
    <xsl:output omit-xml-declaration="yes" indent="yes"/> 
    <xsl:strip-space elements="*"/> 

    <xsl:template match="node()|@*"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
    </xsl:template> 

    <xsl:template match="/"> 
    <xsl:copy> 
     <xsl:copy-of select="@*"/> 
     <xsl:apply-templates/> 
    </xsl:copy> 
    </xsl:template> 

    <xsl:template match="functions:*"> 
    <xsl:variable name="request_function"> 
     <xsl:value-of select="local-name(.)"/> 
    </xsl:variable> 
    <xsl:variable name="request_parameters"> 
     <xsl:for-each select="@*"> 
     <xsl:value-of select="concat('/', name(), '/', .)"/> 
     </xsl:for-each> 
    </xsl:variable> 
    <xsl:variable name="rest_response" select="document(concat('http://foo.com/services/rest/', $request_function, $request_parameters))"/> 
    <xsl:apply-templates select="$rest_response/*/node()"/> 
    </xsl:template> 
</xsl:stylesheet>

謝謝！

來源

2011-12-02 17:49:17 Eric

XSLT - 在REST響應結果轉換XML

回答

相關問題