在Perl中，我如何找到上週四的日期？

Question

可能重複：
In Perl, how can find the date of the previous Monday for a given date?

在Perl中，如何寫一個函數來獲取上週四的日期？今天（11/21），我想得到11/17。如何確定給定的日期是否爲星期日？

Answer 1

看起來像DateTime（這是通常推薦用來在Perl中處理日期的模塊）的工作。這個小例子應該回答兩個您的問題：

use strict; 
use warnings; 

use DateTime; 

my $d = DateTime->now; 

while ($d->day_of_week != 4) { 
    $d->subtract(days => 1); 
} 

print $d->ymd; 

Answer 2

我會用什麼寫的拉爾森，雖然讀localtime reference不會傷害你的。你可以做這樣的事情，以檢查其週日：

($second, $minute, $hour, $dayOfMonth, $month, $yearOffset, 
         $dayOfWeek, $dayOfYear, $daylightSavings) = localtime(); 
if ($dayOfWeek == 0) print("Don't go to work!"); 

Answer 3

如果你想測試全部是本地時間（）的一天的星期幾的數組片很好地工作：

print q(Today is Sunday) if ((localtime)[6]==0) 

Answer 4

您還可以使用Date::Calc：

如何計算的最後一個和下週六爲任何給定的日期？

use Date::Calc qw(Today Day_of_Week Add_Delta_Days 
        Day_of_Week_to_Text Date_to_Text); 

    $searching_dow = 6; # 6 = Saturday 

    @today = Today(); 

    $current_dow = Day_of_Week(@today); 

    if ($searching_dow == $current_dow) 
    { 
     @prev = Add_Delta_Days(@today,-7); 
     @next = Add_Delta_Days(@today,+7); 
    } 
    else 
    { 
     if ($searching_dow > $current_dow) 
     { 
      @next = Add_Delta_Days(@today, 
        $searching_dow - $current_dow); 
      @prev = Add_Delta_Days(@next,-7); 
     } 
     else 
     { 
      @prev = Add_Delta_Days(@today, 
        $searching_dow - $current_dow); 
      @next = Add_Delta_Days(@prev,+7); 
     } 
    } 

    $dow = Day_of_Week_to_Text($searching_dow); 

    print "Today is:  ", ' ' x length($dow), 
           Date_to_Text(@today), "\n"; 
    print "Last $dow was:  ", Date_to_Text(@prev), "\n"; 
    print "Next $dow will be: ", Date_to_Text(@next), "\n"; 

Answer 5

use Date::Calc qw(:all); 

($week, $year) = Week_of_Year(Today());# Week_of_Year(2011,11,21); 
print Date_to_Text(Add_Delta_Days(Monday_of_Week($week - 1,$year),3));#THU - MON = 3 
#output:Thu 17-Nov-2011 

#isSunday? 
Day_of_Week(2011,11,20) == 7 # 7 is Sunday enum code(from 1 : Monday) 

Answer 6

日期::簡單有一個漂亮乾淨的界面。

#!/usr/bin/perl 
use strict; 
use warnings; 
use Date::Simple qw/ today /; 

my $d = today; 

# If today is already Thurs, subtract 1 before searching for prior Thursday. 
# If today is Thurs and you want to capture that (and not Thur a week ago), 
# don't subtract the 1 from $d. 
$d--; 

$d-- while $d->day_of_week != 4;  
print $d->strftime("%Y%m%d"); 

Answer 7

只需localtime和POSIX基本模塊，你可以這樣做：

my @ltime = localtime(); 
my $t 
    = POSIX::mktime((0) x 3 
    , $ltime[3] - (7 - 4 + $ltime[6]) 
    , @ltime[4,5] 
    ); 

這將永遠給你的最後一個星期日前的最後一個星期四。所以如果一天是星期六，它會給你前一週的星期四，但如果是星期天，它會給你最後一個星期四。

如果你喜歡過去的過去週四的計算，你可以這樣做：

my $t 
    = POSIX::mktime((0) x 3 
    , $ltime[3] - $ltime[6] + ($ltime[6] > 4 ? 4 : -3) 
    , @ltime[4,5] 
    ); 

Answer 8

其他崗位使用DateTime太多，但他們有問題，這個帖子的地址。

use DateTime qw(); 
my $dt = DateTime->today(time_zone => 'local'); 
$dt->subtract(days => ($dt->day_of_week - 4) % 7); 
say $dt->ymd(''); # 20111117 

所解決的問題：

• 使用本地日期，而不是在或接近英格蘭的日期。因爲你只處理日期，所以使用today而不是now。
• 避免不必要的循環。

注：

• 返回當前日期是今天是星期四。你接受了同樣的答案，所以我認爲這就是你想要的。

---

更新：以上可以在某些日子一定時間區的失效。 （並不是所有的天在半夜！）解決方案：

use DateTime qw(); 
my $dt = DateTime->now(time_zone => 'local'); 
$dt->set_time_zone('floating'); 
$dt->truncate(to => 'days'); 
$dt->subtract(days => ($dt->day_of_week - 4) % 7); 
say $dt->ymd(''); # 20111117 

的