只計算數字和字母列表中的數字

Question

我是新來的Prolog，我似乎無法自己得到這個答案。

我想要的是，Prolog統計列表中的數字，而不是每個元素。因此，例如：

getnumbers([1, 2, c, h, 4], X). 

應該給我：

X=3 

getnumbers([], 0). 
getnumbers([_ | T], N) :- getnumbers(T, N1), N is N1+1. 

是我得到了什麼，但它顯然給了我在列表中的每個元素。我不知道如何以及在哪裏放一個「只計數」。

Answer 1

考慮使用內置的謂詞（例如，在SWI-Prolog的），並檢查它們的實現，如果你有興趣在如何做到這一點吧：

include(number, List, Ns), length(Ns, N)

Answer 2

當然

，必須檢查要查看它是否滿足條件的元素的類型。

number/1這是你正在尋找的謂詞。

另請參見if/then/else構造，用於遞歸子句。

Answer 3

像往常一樣，當你用列表（SWI和-Prolog的），則可以使用模塊lambda.pl在那裏發現：http://www.complang.tuwien.ac.at/ulrich/Prolog-inedit/lambda.pl

:- use_module(library(lambda)). 

getnumbers(L, N) :- 
    foldl(\X^Y^Z^(number(X) 
      -> Z is Y+1 
      ; Z = Y), 
      L, 0, N). 

Answer 4

這裏使用的Prolog的自然圖案數/ 1的匹配，以及附加條款（下面3）處理不是數字的情況。

% 1 - base recursion 
getnumbers([], 0). 

% 2 - will pass ONLY if H is a number 
getnumbers([H | T], N) :- 
    number(H), 
    getnumbers(T, N1), 
    N is N1+1. 

% 3 - if got here, H CANNOT be a number, ignore head, N is unchanged, recurse tail 
getnumbers([_ | T], N) :- 
    getnumbers(T, N). 

Answer 5

一個共同的序言成語有這種問題是先定義你的斷言對於大衆消費，並把它調用一個「工人」謂詞。通常它會使用某種累加器。對於您的問題，市民的消費謂詞是一樣的東西：

count_numbers(Xs , N) :- 
    count_numbers_in_list(Xs , 0 , N) . 

count_numbers_in_list([] , N , N) . 
count_numbers_in_list([X|Xs] , T , N) :- 
    number(X) , 
    T1 is T+1 , 
    count_numbers_in_list(Xs , T1 , N) 
    . 

您將要構建的遞歸位，所以它是尾遞歸爲好，這意味着遞歸調用取決於什麼，但在數據參數列表。這允許編譯器在每次調用時重用現有的堆棧框架，所以謂詞實際上是迭代的，而不是遞歸的。正確的尾遞歸謂詞可以處理無限長度的列表;一個不會在每次遞歸時分配一個新的堆棧幀並最終放棄它的堆棧。以上count_numbers_in_list/3是尾遞歸。這不是：

getnumbers([H | T], N) :- 
    number(H), 
    getnumbers(T, N1), 
    N is N1+1. 

Answer 6

保持邏輯上純，很容易：使用元謂詞 tcount/3亦隨物化型測試謂詞number_t/2（簡稱number_truth/2）：

number_t(X,Truth) :- number(X), !, Truth = true. 
number_t(X,Truth) :- nonvar(X), !, Truth = false. 
number_t(X,true) :- freeze(X, number(X)). 
number_t(X,false) :- freeze(X,\+number(X)). 

讓我們運行查詢OP建議：

 
?- tcount(number_t,[1,2,c,h,4],N). 
N = 3.          % succeeds deterministically 

請注意，這是單調的：延遲變量綁定總是l聽起來很健康。試想一下：

 
?- tcount(number_t,[A,B,C,D,E],N), A=1, B=2, C=c, D=h, E=4. 
N = 3, A = 1, B = 2, C = c, D = h, E = 4 ; % succeeds, but leaves choice point 
false. 

最後，讓我們看一些下面相當一般查詢的答案：

?- tcount(number_t,[A,B,C],N). 
N = 3, freeze(A, number(A)), freeze(B, number(B)), freeze(C, number(C)) ; 
N = 2, freeze(A, number(A)), freeze(B, number(B)), freeze(C,\+number(C)) ; 
N = 2, freeze(A, number(A)), freeze(B,\+number(B)), freeze(C, number(C)) ; 
N = 1, freeze(A, number(A)), freeze(B,\+number(B)), freeze(C,\+number(C)) ; 
N = 2, freeze(A,\+number(A)), freeze(B, number(B)), freeze(C, number(C)) ; 
N = 1, freeze(A,\+number(A)), freeze(B, number(B)), freeze(C,\+number(C)) ; 
N = 1, freeze(A,\+number(A)), freeze(B,\+number(B)), freeze(C, number(C)) ; 
N = 0, freeze(A,\+number(A)), freeze(B,\+number(B)), freeze(C,\+number(C)).