如何通過NodeMCU從網絡獲取數據

Question

我正在使用NodeMCU v3，並且已經可以在其服務器上發送一些信息。

但是我怎樣才能從其他網頁接收一些信息，比如說開始的時候，一個純文本？

Answer 1

你需要一個HttpClient的與一個Web服務器通信。

開始的好方法是使用HttpClient示例 - > ReuseConnection。

這將允許您製作更多請求，而不是一個。

您可以在Arduino IDE的串行監視器中看到請求的響應。

示例代碼：

注意：你想獲得所需的HTTP頁面 「/ someroute HTTP：//」 替換。

#include <Arduino.h> 

#include <ESP8266WiFi.h> 
#include <ESP8266WiFiMulti.h> 

#include <ESP8266HTTPClient.h> 

#define USE_SERIAL Serial 

ESP8266WiFiMulti WiFiMulti; 

HTTPClient http; 

void setup() { 

    USE_SERIAL.begin(115200); 
    // USE_SERIAL.setDebugOutput(true); 

    USE_SERIAL.println(); 
    USE_SERIAL.println(); 
    USE_SERIAL.println(); 

    for(uint8_t t = 4; t > 0; t--) { 
     USE_SERIAL.printf("[SETUP] WAIT %d...\n", t); 
     USE_SERIAL.flush(); 
     delay(1000); 
    } 

    WiFiMulti.addAP("SSID", "PASSWORD"); 

    // allow reuse (if server supports it) 
    http.setReuse(true); 
} 

void loop() { 
    // wait for WiFi connection 
    if((WiFiMulti.run() == WL_CONNECTED)) { 

     http.begin("http://<IP>:<Port>/someroute"); 

     int httpCode = http.GET(); 
     if(httpCode > 0) { 
      USE_SERIAL.printf("[HTTP] GET... code: %d\n", httpCode); 

      // file found at server 
      if(httpCode == HTTP_CODE_OK) { 
       String payload = http.getString(); 
       USE_SERIAL.println(payload); 
      } 
     } else { 
      USE_SERIAL.printf("[HTTP] GET... failed, error: %s\n", http.errorToString(httpCode).c_str()); 
     } 

     http.end(); 
    } 

    delay(3000); 
}