複雜的「選擇」

Question

這種劃分源XML：

<root> 
    <!-- a and b have the same date entries, c is different --> 
    <variant name="a"> 
    <booking> 
     <date from="2017-01-01" to="2017-01-02" /> 
     <date from="2017-01-04" to="2017-01-06" /> 
    </booking> 
    </variant> 
    <variant name="b"> 
    <booking> 
     <date from="2017-01-01" to="2017-01-02" /> 
     <date from="2017-01-04" to="2017-01-06" /> 
    </booking> 
    </variant> 
    <variant name="c"> 
    <booking> 
     <date from="2017-04-06" to="2017-04-07" /> 
     <date from="2017-04-07" to="2017-04-09" /> 
    </booking> 
    </variant> 
</root> 

我想組的三個變種，以便每個日期相同@from和@to每個變種要相對集中。

我的嘗試是：

<xsl:stylesheet version="2.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output indent="yes"></xsl:output> 

    <xsl:template match="root"> 
    <variants> 
    <xsl:for-each-group select="for $i in variant return $i" group-by="booking/date/@from"> 
     <group> 
     <xsl:attribute name="cgk" select="current-grouping-key()"/> 
     <xsl:copy-of select="current-group()"></xsl:copy-of> 
     </group> 
    </xsl:for-each-group> 
    </variants> 
    </xsl:template> 
</xsl:stylesheet> 

但是這給了太多組。 （如何）這可能實現？

Answer 1

使用composite key和XSLT 3.0，你可以使用

<xsl:template match="root"> 
    <variants> 
     <xsl:for-each-group select="variant" group-by="booking/date/(@from, @to)" composite="yes"> 
      <group key="{current-grouping-key()}"> 
       <xsl:copy-of select="current-group()"/> 
      </group> 
     </xsl:for-each-group> 
    </variants> 
</xsl:template> 

即應集團任何variant元素結合在一起，他們同爲後代date元素序列。

XSLT 3.0由Saxon 9.8（任意版本）或9.7（PE和EE）或2017版Altova XMLSpy/Raptor支持。

使用XSLT 2.0，你可以用string-join()串聯所有這些日期值：與date後裔相同的序列

<xsl:template match="root"> 
    <variants> 
     <xsl:for-each-group select="variant" group-by="string-join(booking/date/(@from, @to), '|')"> 
      <group key="{current-grouping-key()}"> 
       <xsl:copy-of select="current-group()"/> 
      </group> 
     </xsl:for-each-group> 
    </variants> 
</xsl:template> 

像XSLT 3.0解決方案，它只是羣體variant，我不知道這是否足夠或在計算分組鍵之前，是否可能要先排序date後代。在XSLT 3如果你能做到這一點很容易與

 <xsl:for-each-group select="variant" group-by="sort(booking/date,(), function($d) { xs:date($d/@from), xs:date($d/@to) })!(@from, @to)" composite="yes"> 

在線（雖然留下9.8 HE背後，因爲它不支持函數表達式/高階函數，所以你需要移動的排序，以自己用戶定義的xsl:function並在那裏使用xsl:perform-sort）。