如何使用xslt將節點（使用相同名稱）合併爲單節點輸出？

Question

我想合併，如節點：

<sourcePatientInfo>PID-3|1428eab4645a4ce^^^&amp;1.3.6.1.4.1.21367.2008.2.1&amp;ISO</sourcePatientInfo> 
<sourcePatientInfo>PID-5|WILKINS^CHARLES^^^</sourcePatientInfo> 
<sourcePatientInfo>PID-8|M</sourcePatientInfo> 

要這樣的單個節點（不必擔心節點值，我把它處理）：

<sourcePatientInfo> 
     <patientIdentifier> 
     </patientIdentifier> 
     <patientName> 
     </patientName> 
     <patientSex></patientSex> 
    </sourcePatientInfo> 

如果發現幾個崗位： post 1 Post 2

但他們合併與源XML名稱不同的節點。現在我有這個：

<xsl:template match="sourcePatientInfo"> 
    <sourcePatientInfo> 
     <xsl:choose> 
      <xsl:when test="matches(., 'PID-3')"> 
      <patientIdentifier /> 
      </xsl:when> 
      <xsl:when test="matches(., 'PID-5')"> 
      <patientName /> 
      </xsl:when> 
      <xsl:when test="matches(., 'PID-8')"> 
      <patientSex /> 
      </xsl:when>     
     </xsl:choose> 
    </sourcePatientInfo> 
</xsl:template> 

我排除了一些細節，以避免太多的代碼。我得到的是3個單獨的sourcePatientInfo，這是不好的。

任何幫助？謝謝！！！！

Answer 1

這個樣式表：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:l="http://localhost" 
exclude-result-prefixes="l"> 
    <l:n id="PID-3">patientIdentifier</l:n> 
    <l:n id="PID-5">patientName</l:n> 
    <l:n id="PID-8">patientSex</l:n> 
    <xsl:variable name="vNames" select="document('')/*/l:n"/> 
    <xsl:template match="node()|@*"> 
     <xsl:copy> 
      <xsl:apply-templates select="node()|@*"/> 
     </xsl:copy> 
    </xsl:template> 
    <xsl:template match="sourcePatientInfo"/> 
    <xsl:template match="sourcePatientInfo[1]"> 
     <xsl:copy> 
      <xsl:apply-templates 
      select=".|following-sibling::sourcePatientInfo" 
      mode="merge"/> 
     </xsl:copy> 
    </xsl:template> 
    <xsl:template match="sourcePatientInfo" mode="merge"> 
     <xsl:apply-templates 
      select="$vNames[@id=substring-before(current(),'|')]"> 
      <xsl:with-param name="pCurrent" select="."/> 
     </xsl:apply-templates> 
    </xsl:template> 
    <xsl:template match="l:n"> 
     <xsl:param name="pCurrent" select="/.."/> 
     <xsl:element name="{.}"> 
      <xsl:value-of select="substring-after($pCurrent,'|')"/> 
     </xsl:element> 
    </xsl:template> 
</xsl:stylesheet> 

有了這個輸入：

<item> 
    <sourcePatientInfo>PID-3|1428eab4645a4ce^^^&amp;1.3.6.1.4.1.21367.2008.2.1&amp;ISO</sourcePatientInfo> 
    <sourcePatientInfo>PID-5|WILKINS^CHARLES^^^</sourcePatientInfo> 
    <sourcePatientInfo>PID-8|M</sourcePatientInfo> 
</item> 

輸出：

<item> 
    <sourcePatientInfo> 
     <patientIdentifier>1428eab4645a4ce^^^&amp;1.3.6.1.4.1.21367.2008.2.1&amp;ISO</patientIdentifier> 
     <patientName>WILKINS^CHARLES^^^</patientName> 
     <patientSex>M</patientSex> 
    </sourcePatientInfo> 
</item> 

編輯：應用模板內聯地圖的節點爲 「複雜的」 進一步處理。