Haskell - 計算列表中每個不同元素的出現次數

Question

我是Haskell的新手，我只是想寫一個列表理解來計算列表中每個不同值的頻率，但是我遇到了問題最後一部分..

到目前爲止，我有這樣的：

frequency :: Eq a => [a] -> [(Int,a)] 
frequency list = [(count y list,y) | y <- rmdups ] 

某處有問題，涉及rmdups的最後一部分。

count函數需要一個字符，然後字符列表，告訴你如何字符經常發生，代碼如下..

count :: Eq a => a -> [a] -> Int 
count x [] = 0 
count x (y:ys) | x==y = 1+(count x ys) 
       | otherwise = count x ys 

感謝你提前。

Answer 1

您的rmdups功能只是nub從Data.List。

Answer 2

我不得不代替Eq使用Ord因爲使用sort

frequency :: Ord a => [a] -> [(Int,a)] 
frequency list = map (\l -> (length l, head l)) (group (sort list)) 

Answer 3

假設rmdups有那麼你就錯過了它的參數類型

rmdups :: Eq a => [a] -> [a] 

。

frequency :: Eq a => [a] -> [(Int,a)] 
frequency list = [(count y list,y) | y <- rmdups list] 

但是，您得到的錯誤將有助於診斷。

Answer 4

替換rmdups與nub list爲我工作就像一個魅力。

Answer 5

你也可以使用一個關聯數組/有限地圖存儲從列表元素的計數的關聯，而你計算頻率：

import Data.Map (fromListWith, toList) 

frequency :: (Ord a) => [a] -> [(a, Int)] 
frequency xs = toList (fromListWith (+) [(x, 1) | x <- xs]) 

實例：中

> frequency "hello world" 
[(' ',1),('d',1),('e',1),('h',1),('l',3),('o',2),('r',1),('w',1)] 

查看文檔fromListWith和toList。

Answer 6

按照要求，這裏是一個使用Control.Arrow一個解決方案：

frequency :: Ord a => [a] -> [(Int,a)] 
frequency = map (length &&& head) . group . sort 

這是相同的功能，ThePestest的回答，除了

λl -> (length l, head l) 

被替換

-- simplified type signature 
(&&&) :: (a -> b) -> (a -> c) -> a -> (b, c) 

從Control.Arrow。如果你想避免進口，

liftA2 (,) :: Applicative f => f a -> f b -> f (a, b) 

作品，以及（使用(->) r應用型實例）