如何將目錄樹列表寫入文本文件？

Question

我想創建一個批處理文件。當它被調用爲batch.bat MyProject或batch.bat MyProject/時，它將產生以下列表。請注意0​​是MyProject的子目錄。我正在使用Windows 7.

Dir 
Dir/SubDir1 
Dir/SubDir1/SubSubDir1 
Dir/SubDir1/SubSubDir2 
Dir/SubDir2 
Dir/SubDir2/SubSubDir1 
Dir/SubDir2/SubSubDir2 
Dir/SubDir2/SubSubDir3 
Dir/SubDir3 
Dir/SubDir4 

如何將目錄樹列表寫入文本文件？

必須排除文件名。

Answer 1

FORFILES提供了一個簡單的解決方案，但它是慢。該命令從作品批處理文件中同樣或者在命令行上：

forfiles /s /p "c:\MyProject" /m * /c "cmd /v:on /c if @isdir==TRUE (set f=@relpath&echo !f:~3,-1!)" >listing.txt 

如果您運行MyProject的命令作爲當前目錄，那麼你可以刪除該命令的
/p "c:\MyProject"選項。

如果你不介意你的相對路徑被封閉在與每個路徑的前.\報價，則該解決方案更簡單：

forfiles /s /p "c:\MyProject" /m * /c "cmd /c if @isdir==TRUE echo @relpath" >listing.txt 

Answer 2

好的 - 這應該做到這一點。它需要一個參數（根文件夾）。

@ECHO OFF 

SET root=%1 

REM Get the length of the root, to make the path relative later. 
REM See http://stackoverflow.com/questions/5837418/how-do-you-get-the-string-length-in-a-batch-file. 
ECHO %root%>x&FOR %%? IN (x) DO SET /A rootlength=%%~z? - 1&del x 

for /F "tokens=*" %%G in ('DIR %1 /AD /S /B') do (
    CALL :PrintDirectory "%%G" %rootlength% 
) 

GOTO :eof 

:PrintDirectory 
REM %1 Path to the folder 
REM %2 Length of root string. 

REM See http://www.dostips.com/DtTipsStringManipulation.php#Snippets.LeftString for 
REM information on the string manipulation. 

@ECHO OFF 
SET start=%2 
SET absPath=%1 

REM Remove the path root by taking the right-hand side of the string. 
CALL SET relPath=%%absPath:~%start%,-1%% 

ECHO.%relPath% 

您可以通過重定向的結果，一個批處理文件執行：

PrintDirectoryStructure.bat c:\MyProject > out.txt