如何在Haskell中檢查字符串是否比另一個小？

Question

我有兩個字符串作爲參數給一個Haskell函數。

s1小於s2如果s1短於s2或者如果它們具有相同的長度和s1按字典順序比s2小。

我該如何在Haskell中實現？

Answer 1

我會使用類似以下內容：

smaller :: String -> String -> Bool 
smaller s1 s2 | len1 /= len2   = (len1 < len2) 
       | otherwise   = (s1 < s2) 
       where (len1, len2) = (length s1, length s2) 

這裏有一個樣本來看，在擁抱：

 
Main> smaller "b" "aa" 
True 
Main> smaller "aa" "b" 
False 
Main> smaller "this" "that" 
False 
Main> smaller "that" "this" 
True 

Answer 2

試試這個：

compare s1 s2 

（這將返回LT，EQ或GT）。

Answer 3

String是Ord的一個實例，因此您可以使用所有這些方法按字典順序比較字符串。正如Andrew所說，這基本上是compare，但也包括比較運算符(<)等等。

smaller :: Ord a => a -> a -> Bool 
smaller a b = a < b 

這適用於各類實施Ord（實際上只是爲(<)粗包裝），包括String。

Answer 4

正常字符串比較只適用於字典排序，而不適用於字符串的長度。

所以你必須編寫自己的功能，還需要檢查長度：

smaller :: String -> String -> Bool 
smaller s1 s2 | length s1 < length s2 = True 
       | length s1 > length s2 = False 
       | otherwise    = s1 < s2 

或者多一點一般：

compareStrings :: String -> String -> Ordering 
compareStrings s1 s2 | length s1 < length s2 = LT 
        | length s1 > length s2 = GT 
        | otherwise    = compare s1 s2 

例子：

ghci> compare "ab" "z" 
LT 
ghci> compareStrings "ab" "z" 
GT 

---

我們在Monoid附近玩耍上週的大學，我們想出了這個可愛的替代Ord例如：

instance Ord a => Ord [a] where 
    compare = comparing length 
       `mappend` comparing head `mappend` comparing tail 

但是，如果你不很明白這一點，我建議你堅持使用第一個定義;-)

Answer 5

該一個通溶液：

lengthcompare :: Ord a => [a] -> [a] -> Ordering 
lengthcompare = lc EQ 
where 
    lc lx [] [] = lx 
    lc _ [] _ = LT 
    lc _ _ [] = GT 
    lc EQ (v:vs) (w:ws) = lc (compare v w) vs ws 
    lc lx (_:vs) (_:ws) = lc lx vs ws 

smaller :: Ord a => [a] -> [a] -> Bool 
smaller s1 s2 = lengthcompare s1 s2 == LT 

Answer 6

以上由湯姆Lokhorst一個較短的版本的mappend版本：

import Data.Monoid (mappend) 
import Data.Ord (comparing) 

compareStrings :: String -> String -> Ordering 
compareStrings = comparing length `mappend` comparing id 

的另一種方式，以元組的排序的優點：

import Data.Ord (comparing) 
import Control.Arrow ((&&&)) 

compareStrings :: String -> String -> Ordering 
compareStrings = comparing (length &&& id)