刪除所有* c文件中的第一個多行註釋

Question

我在目錄中有很多c文件。每個文件將與多行註釋開始像下面，並開始與包括像

#include<stdio.h>. 

    // This is a c File 

    // This File does sampling the frequency 

    /* This uses the logic ... 
    ..... 
    ..... 
    */ 

#include<stdio.h> 

我需要在所有的.c文件開始刪除所有的註釋行，如果它們存在。有些文件不會有這些註釋行。在這種情況下，它不應該做任何事情。這應該只刪除第一個多行註釋。隨後的多行註釋應該保持原樣。

如何在perl或shell中執行此操作？

在此先感謝

Answer 1

#!/usr/bin/env perl 
use strict; 
use warnings; 
my $skipping = 0; 
while (<>) { 
    m{^\s*//}   and next; 
    m{^\s*/\*.*\*/\s*$} and next; 
    if (m{^\s*/\*}) { 
     $skipping = 1; 
     next; 
    } 
    if (m{^\s*\*/}) { 
     $skipping = 0; 
     next; 
    } 
    next if $skipping; 
    print; 
} 

...或者：

#!/usr/bin/env perl 
use strict; 
use warnings; 
while (<>) { 
    next if  m{^\s*//}; 
    next if  m{^\s*/\*.*\*/\s*$}; 
    next while (m{^\s*/\*}..m{^\s*\*/}); 
    print; 
} 

...如果你只想在第一多行註釋做到這一點，改變了比賽的分隔符範圍從花括號到「？」字符，閱讀這樣的：

next while (m?^\s*/\*?..m?^\s*\*/?); 

Answer 2

如果您確信所有文件開始的包括，你可以在導入前刪除所有行：

perl -i -ne 'print if /^#include/..0' *.c 

Answer 3

我有一個非常簡單的解決方案如果#include可以考慮塞：

use strict; 
use warnings; 
use English qw<$RS>; 
use English qw<@LAST_MATCH_START>; 

*::STDIN = *DATA{IO}; 
my $old_rs = $RS; 
local $RS = "*/"; 
local $_; 

while (<>) { 
    if (m{/[*](?:.(?!:[*]/))*\n(?sm-ix:.(?!:[*]/))*[*]/}m) { 
     substr($_, $LAST_MATCH_START[0]) = ''; 
     print; 
     last; 
    } 
    print; 
    last if m/^\s*#include\b/m; 
} 
$RS = $old_rs; 
print while <>; 

__DATA__ 
##include<stdio.h>. 

    // This is a c File 

    // This File does sampling the frequency 

    /* A mline comment not multi */ 

    /* This uses the logic ... 
    ..... 
    ..... 
    */ 

#include<stdio.h> 

請注意，我不得不改變最初的#include這麼個在劇本作品。對我來說，看起來很簡單，如果我想要多行註釋，最簡單的解決方案是將'*/'作爲我的記錄分隔符，而不是在各行上進行大量切換。

但先行，需要緩衝，並提出瞭解決混亂：

use strict; 
use warnings; 
use English qw<$RS>; 
use English qw<@LAST_MATCH_START>; 

*::STDIN = *DATA{IO}; 
my $old_rs = $RS; 
local $RS = "*/"; 
local $_; 

my ($rin, $rie); 
my $mline = ''; 
my $buffer; 

while (<>) { 
    if (m{/[*](?:.(?!:[*]/))*\n(?sm-ix:.(?!:[*]/))*[*]/}m) { 
     my $split = $LAST_MATCH_START[0]; 
     print substr($_, 0, $split); 
     $mline = substr($_, $split); 
     last; 
    } 
    print; 
} 
$RS = $old_rs; 
while (<>) { 
    $buffer .= $_; 
    if (/^\s*#include\b/) { 
     $mline = ''; 
     last; 
    } 
} 
print $mline, $buffer; 
print while <>; 

__DATA__ 
#include<stdio.h>. 

    // This is a c File 

    // This File does sampling the frequency 

    /* A mutli-line comment not on multiple lines */ 

    /* This uses the logic ... 
    ..... 
    ..... 
    */ 

#include<stdio.h>