如何獲得子串的位置在字符串中批量

Question

獲取的子串的位置，

Set str1=This is Test string 
    Set sstr=Test 

在這裏，我需要得到「測試」的位置（8）。

謝謝...

Answer 1

試試這個：

@echo off &setlocal enabledelayedexpansion 
Set "str1=This is Test string" 
Set "sstr=Test" 
call :strlen str1 len1 
call :strlen sstr len2 
set /a stop=len1-len2 
if %stop% gtr 0 for /l %%i in (0,1,%stop%) do if "!str1:~%%i,%len2%!"=="%sstr%" set /a position=%%i 
if defined position (echo.Position of %sstr% is %position%) else echo."%sstr%" not found in "%str1%" 
goto :eof 

:strlen 
:: list string length up to 8189 (and reports 8189 for any string longer than 8189 
:: function from http://ss64.org/viewtopic.php?pid=6478#p6478 
( setlocal enabledelayedexpansion & set /a "}=0" 
    if "%~1" neq "" if defined %~1 (
     for %%# in (4096 2048 1024 512 256 128 64 32 16) do (
      if "!%~1:~%%#,1!" neq "" set "%~1=!%~1:~%%#!" & set /a "}+=%%#" 
     ) 
     set "%~1=!%~1!0FEDCBA9876543211" & set /a "}+=0x!%~1:~32,1!!%~1:~16,1!" 
    ) 
) 
endlocal & set /a "%~2=%}%" & exit /b 
endlocal 

如果STR1％％包含多個％SSTR％，代碼將找到的最後位置。

Answer 2

@echo OFF 
SETLOCAL 
Set "str1=This is Test string" 
Set "sstr=Test" 
SET stemp=%str1%&SET pos=0 
:loop 
SET /a pos+=1 
echo %stemp%|FINDSTR /b /c:"%sstr%" >NUL 
IF ERRORLEVEL 1 (
SET stemp=%stemp:~1% 
IF DEFINED stemp GOTO loop 
SET pos=0 
) 

ECHO Pos of "%sstr%" IN "%str1%" = %pos% 

（這將返回 「9」，計數爲 「1」 的定義是在用戶的頭腦...第一位置。）

Answer 3

和一個額外的替代方法：

@echo off &setlocal enabledelayedexpansion 
Set "str1=This is Test string" 
Set "sstr=Test" 
set /a position=0 
Set "sst0=!str1:*%sstr%=!" 
if "%sst0%"=="%str1%" echo "%sstr%" not found in "%str1%"&goto :eof 
Set "sst1=!str1:%sstr%%sst0%=!" 
if "%sst1%" neq "" for /l %%i in (0,1,8189) do if "!sst1:~%%i,1!" neq "" set /a position+=1 
echo.Position of %sstr% is %position% 
endlocal 

如果％str1％包含多於一個％sstr％，代碼將找到第一個位置。